Retrieve Email and Parse Email in Delphi - Tutorial¶

Installation¶

EAGetMail is a POP3 and IMAP4 component which supports all operations of POP3/IMAP4/MIME/Exchange Web Service/WebDAV/SSL/S/MIME protocol. Before you can use the following example codes, you should download the EAGetMail Installer and install it on your machine at first. Full sample projects are included in this installer.

Add Reference¶

To use EAGetMail ActiveX Object in your Delphi project, the first step is “Add Unit file of EAGetMail to your project”. Please go to C:\Program Files\EAGetMail\Include\delphi or C:\Program Files (x86)\EAGetMail\Include\delphi folder, find EAGetMailObjLib_TLB.pas, and then copy this file to your project folder.

// include EAGetMailObjLib_TLB unit to your Delphi Project
unit Unit1;

interface

uses
Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
Dialogs, EAGetMailObjLib_TLB, StdCtrls;

Then you can start to use it in your Delphi Project.

You can also create EAGetMailObjLib_TLB.pas manually by Delphi like this:

• Delphi 7 or eariler version

  First of all, create a standard delphi project: select menu Project -> Import Type Library, checked EAGetMail ActiveX Object and click Create Unit. Then include EAGetMailObjLib_TLB in your project.

  

• Delphi XE or later version

  First of all, create a standard delphi project: select menu Component -> Import component... -> Import a type library -> checked EAGetMail ActiveX Object, have Generate Component Wrapper checked and click “Create Unit”. Then include EAGetMailObjLib_TLB in your project.

[Delphi Example - Retrieve email from POP3 server]¶

Now add the following codes to the project. The following codes demonstrate how to retrieve email from a POP3 mail account. It downloads emails from POP3 server and deletes the email after the email is retrieved.

In order to run it correctly, please change email server, user, password, folder, file name values.

unit Unit1;

interface

uses
    Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
    Dialogs, StdCtrls, EAGetMailObjLib_TLB;

type
    TForm1 = class(TForm)
        Button1: TButton;
        procedure Button1Click(Sender: TObject);
    private
        { Private declarations }
    public
        { Public declarations }
    end;

const
    MailServerPop3 = 0;
    MailServerImap4 = 1;
    MailServerEWS = 2;
    MailServerDAV = 3;
    MailServerMsGraph = 4;


var
    Form1: TForm1;

implementation

{$R *.dfm}

procedure TForm1.Button1Click(Sender: TObject);
var
    oServer: TMailServer;
    oClient: TMailClient;
    oTools: TTools;
    oMail: IMail;
    infos: IMailInfoCollection;
    oInfo: IMailInfo;
    localInbox, fileName: WideString;
    i: Integer;
begin

    try
        // set current thread code page to system default code page.
        SetThreadLocale(GetSystemDefaultLCID());
        oTools := TTools.Create(Application);

        // Create a folder named "inbox" under
        // current directory to store the email files
        localInbox := GetCurrentDir() + '\inbox';
        oTools.CreateFolder(localInbox);

        oServer := TMailServer.Create(Application);
        oServer.Server := 'pop3.emailarchitect.net';
        oServer.User := 'test@emailarchitect.net';
        oServer.Password := 'testpassword';
        oServer.Protocol := MailServerPop3;

        // Enable SSL/TLS Connection, most modern email server require SSL/TLS connection by default.
        oServer.SSLConnection := true;
        // Set 995 SSL POP3 port
        oServer.Port := 995;

        // If your POP3 server doesn't deploy SSL connection
        // Please use
        // oServer.SSLConnection := false;
        // oServer.Port := 110;

        oClient := TMailClient.Create(Application);
        oClient.LicenseCode := 'TryIt';

        oClient.Connect1(oServer.DefaultInterface);
        ShowMessage('Connected!');

        infos := oClient.GetMailInfoList();
        ShowMessage(Format('Total %d email(s)', [infos.Count]));

        for i := 0 to infos.Count - 1 do
            begin
                oInfo := infos.Item[i];

                ShowMessage(Format('Index: %d; Size: %d; UIDL: ' + oInfo.UIDL,
                [oInfo.Index, oInfo.Size]));

                // Generate a random file name by current local datetime,
                // You can use your method to generate the filename if you do not like it
                fileName := localInbox + '\' + oTools.GenFileName(i) + '.eml';

                // Receive email from POP3 server
                oMail := oClient.GetMail(oInfo);

                ShowMessage('From: ' + oMail.From.Address + #13#10 +
                    'Subject: ' + oMail.Subject);

                // Save email to local disk
                oMail.SaveAs(fileName, true);

                // Mark email as deleted from POP3 server
                oClient.Delete(oInfo);
            end;

        // Quit and expunge emails marked as deleted from POP3 server
        oClient.Quit;

    except
        on ep:Exception do
            ShowMessage('Error: ' + ep.Message);
    end;

end;

end.

If you set everything right, you can get emails in the mail folder. If the codes threw exception, then please have a look at the following section.

“No Such Host” Error¶

This error means DNS server cannot resolve POP3 server, you should check if you input correct server address. If your server address is correct, you should check if your DNS server setting is correct.

Common “Socket/Networking Connection” Error¶

This error means there is a problem with networking connection to POP3 server. You can use Windows built-in Telnet command to detect the networking connection.

Using Telnet to detect networking connection to POP3 server¶

Under DOS command prompt, input telnet [serveraddress] [port]

telnet mail.emailarchitect.net 110

If the networking connection to your POP3 server is good, it should return a message like +OK .... If it returns Could not open connection to ..., that means the networking connection to POP3 server is bad, or outbound 110 port is blocked by anti-virus software, firewall or ISP. Please have a look at the following screenshot:

POP3 110, 995 port, IMAP4 143, 993 port and SSL¶

• 110 port is the default POP3 server port to receive email. 995 port is the common POP3 SSL port used to receive email over implicit SSL connection.
• 143 port is the default IMAP4 server port, 993 port is the common port for IMAP4 SSL.

If you use telnet to test 995/993 port, it doesn’t return the +OK..., because it requires SSL hand shake. If the connection is ok, telnet returns a flash cursor.

Now SSL is commonly used, many email servers require SSL connection such as Gmail, Outlook, Office 365 and Yahoo. In this case you should set MailServer.SSLConnection to true and change MailServer.Port to 995 (POP3) or 993 (IMAP4).

“-ERR user authentication” Error¶

This error means user authentication is failed, you should check whether you input correct user/password. Password is always case-sensitive.

Other error returned by POP3 server¶

If POP3 server returns an error, it usually returns description about this error. You can use the following codes to generate a log file to learn all POP3 session between client and server.

[Delphi - Using log file to detect POP3 server response - Example]

oClient.LogFileName := 'd:\pop3.txt';