Retrieve Email and Parse Email in VB.NET - Tutorial¶

Installation¶

EAGetMail is a POP3 and IMAP4 component which supports all operations of POP3/IMAP4/MIME/Exchange Web Service/WebDAV/SSL/S/MIME protocol. Before you can use the following example codes, you should download the EAGetMail Installer and install it on your machine at first. Full sample projects are included in this installer.

Install from NuGet

You can also install the run-time assembly by NuGet. Run the following command in the NuGet Package Manager Console:

Install-Package EAGetMail

Add Reference¶

To use EAGetMail POP3 & IMAP Component in your project, the first step is “Add reference of EAGetMail to your project”. Please create or open your project with Visual Studio, then go to menu -> Project -> Add Reference -> .NET -> Browse..., and select Installation Path\Lib\net[version]\EAGetMail{version}.dll from installation path, click Open-> OK, the reference will be added to the project, you can start to use it to retrieve email and parse email in your project.

.NET Assembly¶

Because EAGetMail has separate builds for .Net Framework, please refer to the following table and choose the correct dll.

Separate builds of run-time assembly for .Net Framework 2.0, 4.0, 4.5, 4.6.1, 4.7.2, 4.8.1, .NET 6.0, NET 7.0, .NET 8.0, .NET Standard 2.0 and .Net Compact Framework 2.0, 3.5.

[VB.NET Example - Retrieve email from POP3 server]¶

Now add the following codes to the project. The following codes demonstrate how to retrieve email from a POP3 mail account. It downloads emails from POP3 server and deletes the email after the email is retrieved.

In order to run it correctly, please change email server, user, password, folder, file name values.

Imports System.Globalization
Imports System.Text
Imports System.IO
Imports EAGetMail 'imports EAGetMail namespace

Module Module1

    Function _generateFileName(ByVal sequence As Integer) As String
        Dim currentDateTime As DateTime = DateTime.Now
        Return String.Format("{0}-{1:000}-{2:000}.eml",
                            currentDateTime.ToString("yyyyMMddHHmmss", New CultureInfo("en-US")),
                            currentDateTime.Millisecond,
                            sequence)
    End Function

    Sub Main()

        Try
            ' Create a folder named "inbox" under current directory
            ' to save the email retrieved.
            Dim localInbox As String = String.Format("{0}\inbox", Directory.GetCurrentDirectory())

            ' If the folder is not existed, create it.
            If Not Directory.Exists(localInbox) Then
                Directory.CreateDirectory(localInbox)
            End If

            Dim oServer As New MailServer("pop3.emailarchitect.net",
                        "test@emailarchitect.net",
                        "testpassword",
                        ServerProtocol.Pop3)

            ' Enable SSL/TLS connection, most modern email server require SSL/TLS connection by default.
            oServer.SSLConnection = True
            oServer.Port = 995

            ' If your server doesn't support SSL/TLS connection, please use the following codes
            ' oServer.SSLConnection = False
            ' oServer.Port = 110

            Console.WriteLine("Connecting server ...")

            Dim oClient As New MailClient("TryIt")
            oClient.Connect(oServer)

            Dim infos As MailInfo() = oClient.GetMailInfos()
            Console.WriteLine("Total {0} email(s)", infos.Length)

            For i As Integer = 0 To infos.Length - 1
                Dim info As MailInfo = infos(i)
                Console.WriteLine("Index: {0}; Size: {1}; UIDL: {2}",
                        info.Index, info.Size, info.UIDL)

                ' Retrieve email from POP3 server
                Dim oMail As Mail = oClient.GetMail(info)

                Console.WriteLine("From: {0}", oMail.From.ToString())
                Console.WriteLine("Subject: {0}" & vbCr & vbLf, oMail.Subject)

                ' Generate an unqiue email file name based on date time.
                Dim fileName As String = _generateFileName(i + 1)
                Dim fullPath As String = String.Format("{0}\{1}", localInbox, fileName)

                ' Save email to local disk
                oMail.SaveAs(fullPath, True)

                ' Mark email as deleted from POP3 server.
                oClient.Delete(info)

            Next

            ' Quit and expunge emails marked as deleted from POP3 server.
            oClient.Quit()
            Console.WriteLine("Completed!")

        Catch ep As Exception
            Console.WriteLine(ep.Message)
        End Try

    End Sub
End Module

If you set everything right, you can get emails in the mail folder. If the codes threw exception, then please have a look at the following section.

“No Such Host” Error¶

This error means DNS server cannot resolve POP3 server, you should check if you input correct server address. If your server address is correct, you should check if your DNS server setting is correct.

Common “Socket/Networking Connection” Error¶

This error means there is a problem with networking connection to POP3 server. You can use Windows built-in Telnet command to detect the networking connection.

Using Telnet to detect networking connection to POP3 server¶

Under DOS command prompt, input telnet [serveraddress] [port]

telnet mail.emailarchitect.net 110

If the networking connection to your POP3 server is good, it should return a message like +OK .... If it returns Could not open connection to ..., that means the networking connection to POP3 server is bad, or outbound 110 port is blocked by anti-virus software, firewall or ISP. Please have a look at the following screenshot:

POP3 110, 995 port, IMAP4 143, 993 port and SSL¶

• 110 port is the default POP3 server port to receive email. 995 port is the common POP3 SSL port used to receive email over implicit SSL connection.
• 143 port is the default IMAP4 server port, 993 port is the common port for IMAP4 SSL.

If you use telnet to test 995/993 port, it doesn’t return the +OK..., because it requires SSL hand shake. If the connection is ok, telnet returns a flash cursor.

Now SSL is commonly used, many email servers require SSL connection such as Gmail, Outlook, Office 365 and Yahoo. In this case you should set MailServer.SSLConnection to true and change MailServer.Port to 995 (POP3) or 993 (IMAP4).

“-ERR user authentication” Error¶

This error means user authentication is failed, you should check whether you input correct user/password. Password is always case-sensitive.

Other error returned by POP3 server¶

If POP3 server returns an error, it usually returns description about this error. You can use the following codes to generate a log file to learn all POP3 session between client and server.

[VB.NET - Using log file to detect POP3 server response - Example]

oClient.LogFileName = "d:\pop3.txt"