Using UIDL Function to Mark the Email has been downloaded/read in VB.NET

In previous section, I introduced how to use event handler. In this section, I will introduce how to use UIDL function to mark the email has been downloaded in VB.NET.

Introduction

If you want to leave a copy of email on the server, you should not call Delete method. However, there is a problem, how can you know if the email has already been downloaded? If there is a way to identify the downloaded email, you can avoid downloading the duplicated email from your POP3/IMAP4 server.

Note

Remarks: All of examples in this section are based on first section: A simple VB.NET project. To compile and run the following example codes successfully, please click here to learn how to create the test project and add reference to your project.

[VB.NET Example - IMAP4 Solution]

Every email has a unique identifier (UIDL) on IMAP4 server. It is a 32bit integer and it is always unique in your email account life time. So we can use the integer as file name to identify if the email has been downloaded. In order to run it correctly, please change email server, user, password, folder, file name values.

Imports System.Globalization
Imports System.Text
Imports System.IO
Imports EAGetMail 'imports EAGetMail namespace

Module Module1

    Function _generateFileName(ByVal sequence As Integer) As String
        Dim currentDateTime As DateTime = DateTime.Now
        Return String.Format("{0}-{1:000}-{2:000}.eml",
                            currentDateTime.ToString("yyyyMMddHHmmss", New CultureInfo("en-US")),
                            currentDateTime.Millisecond,
                            sequence)
    End Function

    Sub Main()

        Try
            ' Create a folder named "inbox" under current directory
            ' to save the email retrieved.
            Dim localInbox As String = String.Format("{0}\inbox", Directory.GetCurrentDirectory())

            ' If the folder is not existed, create it.
            If Not Directory.Exists(localInbox) Then
                Directory.CreateDirectory(localInbox)
            End If

            Dim oServer As New MailServer("imap.emailarchitect.net",
                        "test@emailarchitect.net",
                        "testpassword",
                        ServerProtocol.Imap4)

            ' Enable SSL/TLS connection, most modern email server require SSL/TLS connection by default.
            oServer.SSLConnection = True
            oServer.Port = 993

            ' If your server doesn't support SSL/TLS connection, please use the following codes
            ' oServer.SSLConnection = False
            ' oServer.Port = 143

            Console.WriteLine("Connecting server ...")

            Dim oClient As New MailClient("TryIt")
            oClient.Connect(oServer)

            Dim infos As MailInfo() = oClient.GetMailInfos()
            Console.WriteLine("Total {0} email(s)", infos.Length)

            For i As Integer = 0 To infos.Length - 1
                Dim info As MailInfo = infos(i)
                Console.WriteLine("Index: {0}; Size: {1}; UIDL: {2}",
                        info.Index, info.Size, info.UIDL)

                ' Using IMAP UIDL as the file name
                Dim fileName As String = String.Format("{0}.eml", info.UIDL)
                Dim fullPath As String = String.Format("{0}\{1}", localInbox, fileName)

                If File.Exists(fullPath) Then
                    ' This email has been downloaded,  do not download it again.
                    Continue For
                End If

                ' Retrieve email from IMAP server
                Dim oMail As Mail = oClient.GetMail(info)

                Console.WriteLine("From: {0}", oMail.From.ToString())
                Console.WriteLine("Subject: {0}" & vbCr & vbLf, oMail.Subject)

                ' Save email to local disk
                oMail.SaveAs(fullPath, True)

                ' Do not delete email from IMAP4 server.
            Next

            ' Quit and expunge emails marked as deleted from IMAP server.
            oClient.Quit()
            Console.WriteLine("Completed!")

        Catch ep As Exception
            Console.WriteLine(ep.Message)
        End Try

    End Sub
End Module

POP3/IMAP4/Exchange Web Service/WebDAV Solution

There is a little bit different in POP3 server. The UIDL is only unique in the email life time. That means if the email was deleted from the server, other email can use the old unique identifier. Another problem is: UIDL in POP3 server can be any number or characters, so we cannot use UIDL as the file name, because UIDL may contain invalid characters for file name.

UIDL is also unique in Exchange Web Service/WebDAV, but the UIDL is string but not integer. UIDL in Exchange server may contain invalid characters for file name, so we cannot use UIDL as the file name either.

To solve this problem, we have to store the UIDL to a txt file and synchronize it with server every time.

Please have a look at the following example code. It can work with POP3/IMAP4/Exchange Web Service/WebDAV protocols.

Imports System.Globalization
Imports System.Text
Imports System.IO
Imports EAGetMail 'imports EAGetMail namespace

Module Module1

    Function _generateFileName(ByVal sequence As Integer) As String
        Dim currentDateTime As DateTime = DateTime.Now
        Return String.Format("{0}-{1:000}-{2:000}.eml",
                            currentDateTime.ToString("yyyyMMddHHmmss", New CultureInfo("en-US")),
                            currentDateTime.Millisecond,
                            sequence)
    End Function

    Sub Main()

        Dim isUidlLoaded As Boolean = False
        Dim isLeaveCopy As Boolean = True ' leave a copy of message on server

        ' UIDL is the identifier of every email on POP3/IMAP4/Exchange server, to avoid retrieve
        ' the same email from server more than once, we record the email UIDL retrieved every time
        ' if you delete the email from server every time and not to leave a copy of email on
        ' the server, then please remove all the function about uidl.
        ' UIDLManager wraps the function to write/read uidl record from a text file.
        Dim oUIDLManager As UIDLManager = New UIDLManager()

        Try
            ' Create a folder named "inbox" under current directory
            ' to save the email retrieved.
            Dim localInbox As String = String.Format("{0}\inbox", Directory.GetCurrentDirectory())
            Dim uidlFile As String = String.Format("{0}\uidl.txt", localInbox)

            ' If the folder is not existed, create it.
            If Not Directory.Exists(localInbox) Then
                Directory.CreateDirectory(localInbox)
            End If

            Dim oServer As New MailServer("pop3.emailarchitect.net",
                        "test@emailarchitect.net",
                        "testpassword",
                        ServerProtocol.Pop3)

            ' Enable SSL/TLS connection, most modern email server require SSL/TLS connection by default.
            oServer.SSLConnection = True
            oServer.Port = 995

            ' If your server doesn't support SSL/TLS connection, please use the following codes
            ' oServer.SSLConnection = False
            ' oServer.Port = 110

            ' Load existed uidl records to UIDLManager
            oUIDLManager.Load(uidlFile)
            isUidlLoaded = True

            Console.WriteLine("Connecting server ...")

            Dim oClient As New MailClient("TryIt")
            oClient.Connect(oServer)

            Dim infos As MailInfo() = oClient.GetMailInfos()
            Console.WriteLine("Total {0} email(s)", infos.Length)

            ' Remove the local uidl that is not existed on the server,
            oUIDLManager.SyncUIDL(oServer, infos)
            oUIDLManager.Update()

            For i As Integer = 0 To infos.Length - 1
                Dim info As MailInfo = infos(i)

                If oUIDLManager.FindUIDL(oServer, info.UIDL) IsNot Nothing Then
                    ' This email has been downloaded before.
                    Continue For
                End If

                Console.WriteLine("Retrieving {0}/{1}...", i + 1, infos.Length)

                ' Retrieve email from POP3 server
                Dim oMail As Mail = oClient.GetMail(info)

                Console.WriteLine("From: {0}", oMail.From.ToString())
                Console.WriteLine("Subject: {0}" & vbCr & vbLf, oMail.Subject)

                ' Generate an unqiue email file name based on date time.
                Dim fileName As String = _generateFileName(i + 1)
                Dim fullPath As String = String.Format("{0}\{1}", localInbox, fileName)

                ' Save email to local disk
                oMail.SaveAs(fullPath, True)

                If isLeaveCopy Then
                    ' Add uidl to uidl file to avoid we retrieve it next time.
                    oUIDLManager.AddUIDL(oServer, info.UIDL, fileName)
                Else
                    Console.WriteLine("Deleting ...")
                    oClient.Delete(info)

                    ' Remove UIDL from local uidl file.
                    oUIDLManager.RemoveUIDL(oServer, info.UIDL)
                End If

            Next

            ' Quit and expunge emails marked as deleted from POP3 server.
            oClient.Quit()
            Console.WriteLine("Completed!")

        Catch ep As Exception
            Console.WriteLine(ep.Message)
        End Try

        ' Update the uidl list to local uidl file and then we can load it next time.
        If isUidlLoaded Then
            oUIDLManager.Update()
        End If

    End Sub
End Module

UIDLManager Object

With EAGetMail 4.0, it provides a new class named “UIDLManager”. This object provides an easy way to maintain UIDL between your server and your local client. How does it work? It stores UIDL collection to a local disk file and you can use this object to add, remove and search UIDL with this local file. Then you don’t have to handle UIDL in your code. Please click here to learn more detail.

Mark Email as Read on IMAP4/Exchange Server

With IMAP4/Exchange Web Service/WebDAV protocol, you can also mark the email as read on the server, but POP3 doesn’t support this feature. Please refer to MarkAsRead method to learn more detail.

[VB.NET Example - Retrieve unread/new email in IMAP4/EWS/WebDAV]

Because IMAP/EWS/WebDAV support read mail flag, with this feature, we can also retrieve unread/new email only from IMAP4/EWS/WebDAV like this

Imports System.Globalization
Imports System.Text
Imports System.IO
Imports EAGetMail 'imports EAGetMail namespace

Module Module1

    Function _generateFileName(ByVal sequence As Integer) As String
        Dim currentDateTime As DateTime = DateTime.Now
        Return String.Format("{0}-{1:000}-{2:000}.eml",
                            currentDateTime.ToString("yyyyMMddHHmmss", New CultureInfo("en-US")),
                            currentDateTime.Millisecond,
                            sequence)
    End Function

    Sub Main()

        Try
            ' Create a folder named "inbox" under current directory
            ' to save the email retrieved.
            Dim localInbox As String = String.Format("{0}\inbox", Directory.GetCurrentDirectory())

            ' If the folder is not existed, create it.
            If Not Directory.Exists(localInbox) Then
                Directory.CreateDirectory(localInbox)
            End If

            Dim oServer As New MailServer("imap.emailarchitect.net",
                        "test@emailarchitect.net",
                        "testpassword",
                        ServerProtocol.Imap4)

            ' Enable SSL/TLS connection, most modern email server require SSL/TLS connection by default.
            oServer.SSLConnection = True
            ' Set 993 IMAP SSL Port
            oServer.Port = 993

            Console.WriteLine("Connecting server ...")

            Dim oClient As New MailClient("TryIt")
            oClient.Connect(oServer)

            ' retrieve unread/new email only
            oClient.GetMailInfosParam.Reset()
            oClient.GetMailInfosParam.GetMailInfosOptions = GetMailInfosOptionType.NewOnly

            Dim infos As MailInfo() = oClient.GetMailInfos()
            Console.WriteLine("Total {0} unread email(s)", infos.Length)

            For i As Integer = 0 To infos.Length - 1
                Dim info As MailInfo = infos(i)
                Console.WriteLine("Index: {0}; Size: {1}; UIDL: {2}",
                        info.Index, info.Size, info.UIDL)

                ' Retrieve email from IMAP server
                Dim oMail As Mail = oClient.GetMail(info)

                Console.WriteLine("From: {0}", oMail.From.ToString())
                Console.WriteLine("Subject: {0}" & vbCr & vbLf, oMail.Subject)

                ' Generate an unqiue email file name based on date time.
                Dim fileName As String = _generateFileName(i + 1)
                Dim fullPath As String = String.Format("{0}\{1}", localInbox, fileName)

                ' Save email to local disk
                oMail.SaveAs(fullPath, True)

                 ' mark unread email as read, next time this email won't be retrieved again
                If Not info.Read Then
                    oClient.MarkAsRead(info, True)
                End If

                ' if you don't want to leave a copy on server, please use
                ' oClient.Delete(info)
                ' instead of MarkAsRead

            Next

            ' Quit and expunge emails marked as deleted from IMAP server.
            oClient.Quit()
            Console.WriteLine("Completed!")

        Catch ep As Exception
            Console.WriteLine(ep.Message)
        End Try

    End Sub
End Module

Next Section

At next section I will introduce how to download email in background.

Appendix

Comments

If you have any comments or questions about above example codes, please click here to add your comments.