Retrieve Email from Exchange Server with WebDAV protocol in VB.NET¶

In previous section, I introduced how to retrieve email from Exchange Server with Web Service (EWS) protocol in VB.NET. In this section, I will introduce the WebDAV protocol (Exchange 2000/2003).

Sections:

Introduction
[VB.NET Example - Retrieve email from Exchange Inbox]
[VB.NET Example - Retrieve email from “Deleted Items”]

Introduction¶

Exchange WebDAV protocol is similar with IMAP4 protocol. First of all, it supports retrieving email from different mail folder and folder management. Secondly, Exchange WebDAV supports mail read flag management. Therefore, we can do more things with Exchange server. To better understand the WebDAV protocol, please see the following examples.

Exchange Server supports POP3/IMAP4 protocol as well, but in Exchange 2007 or later version, POP3/IMAP4 service is disabled by default. If you don’t want to use POP3/IMAP4 to download email from Exchange Server, you can use Exchange Web Service (Exchange 2007/2010 or later version) or WebDAV (Exchange 2000/2003) protocol.

For Exchange Server 2007 or later version, WebDAV service is also disabled by default, so please use Exchange Web Service (EWS) instead of WebDAV protocol.

Note

Remarks: All of examples in this section are based on first section: A simple VB.NET project. To compile and run the following example codes successfully, please click here to learn how to create the test project and add reference to your project.

[VB.NET Example - Retrieve email from Exchange Inbox]¶

The following example codes demonstrate how to use EAGetMail to download email from Exchange server default mailbox using WebDAV protocol. In order to run it correctly, please change email server, user, password, folder, file name values.

Note

To get the full sample projects, please refer to Samples section.

Imports System.Globalization
Imports System.Text
Imports System.IO
Imports EAGetMail 'imports EAGetMail namespace

Module Module1

Function _generateFileName(ByVal sequence As Integer) As String
    Dim currentDateTime As DateTime = DateTime.Now
    Return String.Format("{0}-{1:000}-{2:000}.eml",
                        currentDateTime.ToString("yyyyMMddHHmmss", New CultureInfo("en-US")),
                        currentDateTime.Millisecond,
                        sequence)
End Function

Sub Main()

    Try
        ' Create a folder named "inbox" under current directory
        ' to save the email retrieved.
        Dim localInbox As String = String.Format("{0}\inbox", Directory.GetCurrentDirectory())

        ' If the folder is not existed, create it.
        If Not Directory.Exists(localInbox) Then
            Directory.CreateDirectory(localInbox)
        End If

       ' Please use domain\user or full email address as the user name.
        Dim oServer As New MailServer("exch.emailarchitect.net",
                "emailarchitect.net\tester",
                "testpassword",
                ServerProtocol.ExchangeWebDAV)

        ' If your Exchange WebDAV server requires SSL connection,
        ' Please add the following codes:
        ' oServer.SSLConnection = True

        Console.WriteLine("Connecting server ...")

        Dim oClient As New MailClient("TryIt")
        oClient.Connect(oServer)

        Dim infos As MailInfo() = oClient.GetMailInfos()
        Console.WriteLine("Total {0} email(s)", infos.Length)

        For i As Integer = 0 To infos.Length - 1
            Dim info As MailInfo = infos(i)
            Console.WriteLine("Index: {0}; Size: {1}; UIDL: {2}",
                    info.Index, info.Size, info.UIDL)

            ' Retrieve email from Exchange server
            Dim oMail As Mail = oClient.GetMail(info)

            Console.WriteLine("From: {0}", oMail.From.ToString())
            Console.WriteLine("Subject: {0}" & vbCr & vbLf, oMail.Subject)

            ' Generate an unqiue email file name based on date time.
            Dim fileName As String = _generateFileName(i + 1)
            Dim fullPath As String = String.Format("{0}\{1}", localInbox, fileName)

            ' Save email to local disk
            oMail.SaveAs(fullPath, True)

            ' Mark email as deleted from Exchange server.
            oClient.Delete(info)

        Next

        ' Quit and expunge emails marked as deleted from Exchange server.
        oClient.Quit()
        Console.WriteLine("Completed!")

    Catch ep As Exception
        Console.WriteLine(ep.Message)
    End Try

End Sub

End Module

Because Exchange WebDAV protocol supports folder access, so we can retrieve email from other mailbox rather than default “INBOX”. POP3 protocol doesn’t support this feature.

[VB.NET Example - Retrieve email from “Deleted Items”]¶

The following example codes demonstrate how to retrieve emails from “Deleted Items” in an Exchange account.

Note

To get the full sample projects, please refer to Samples section.

Imports System.Globalization
Imports System.Text
Imports System.IO
Imports EAGetMail 'imports EAGetMail namespace

Module Module1

    ' if you want to search sub folder, use parentfolder\subfolder as folderPath
    ' for example: inbox\mysubfolder
    Function FindFolder(ByVal folderPath As String, ByRef folders As Imap4Folder()) As Imap4Folder
        For i As Integer = 0 To folders.Length - 1
            Dim folder As Imap4Folder = folders(i)
            ' Folder was found.
            If String.Compare(folder.LocalPath, folderPath, True) = 0 Then
                Return folder
            End If

            folder = FindFolder(folderPath, folder.SubFolders)
            If Not (folder Is Nothing) Then
                Return folder
            End If
        Next

        ' No folder found
        Return Nothing
    End Function

    Function _generateFileName(ByVal sequence As Integer) As String
        Dim currentDateTime As DateTime = DateTime.Now
        Return String.Format("{0}-{1:000}-{2:000}.eml",
                            currentDateTime.ToString("yyyyMMddHHmmss", New CultureInfo("en-US")),
                            currentDateTime.Millisecond,
                            sequence)
    End Function

    Sub Main()

        Try
            ' Create a folder named "inbox" under current directory
            ' to save the email retrieved.
            Dim localInbox As String = String.Format("{0}\inbox", Directory.GetCurrentDirectory())

            ' If the folder is not existed, create it.
            If Not Directory.Exists(localInbox) Then
                Directory.CreateDirectory(localInbox)
            End If

            ' Please use domain\user or full email address as the user name.
            Dim oServer As New MailServer("exch.emailarchitect.net",
                    "emailarchitect.net\tester",
                    "testpassword",
                    ServerProtocol.ExchangeWebDAV)

            ' If your Exchange WebDAV server requires SSL connection,
            ' Please add the following codes:
            ' oServer.SSLConnection = True

            Console.WriteLine("Connecting server ...")

            Dim oClient As New MailClient("TryIt")
            oClient.Connect(oServer)

            ' Lookup folder based on path.
            Dim folder As Imap4Folder = FindFolder("Deleted Items", oClient.GetFolders())
            If folder Is Nothing Then
                Throw New Exception("Folder was not found")
            End If

            ' Select this folder
            oClient.SelectFolder(folder)

            Dim infos As MailInfo() = oClient.GetMailInfos()
            Console.WriteLine("Total {0} email(s)", infos.Length)

            For i As Integer = 0 To infos.Length - 1
                Dim info As MailInfo = infos(i)
                Console.WriteLine("Index: {0}; Size: {1}; UIDL: {2}",
                        info.Index, info.Size, info.UIDL)

                ' Retrieve email from Exchange server
                Dim oMail As Mail = oClient.GetMail(info)

                Console.WriteLine("From: {0}", oMail.From.ToString())
                Console.WriteLine("Subject: {0}" & vbCr & vbLf, oMail.Subject)

                ' Generate an unqiue email file name based on date time.
                Dim fileName As String = _generateFileName(i + 1)
                Dim fullPath As String = String.Format("{0}\{1}", localInbox, fileName)

                ' Save email to local disk
                oMail.SaveAs(fullPath, True)

                ' Mark email as deleted from Exchange server.
                oClient.Delete(info)

            Next

            ' Quit and expunge emails marked as deleted from Exchange server.
            oClient.Quit()
            Console.WriteLine("Completed!")

        Catch ep As Exception
            Console.WriteLine(ep.Message)
        End Try

    End Sub
End Module

Next Section

At next section I will introduce how to retrieve email over SSL connection.

Tutorial Index

Retrieve Email from Exchange Server with WebDAV protocol in VB.NET¶

Introduction¶

[VB.NET Example - Retrieve email from Exchange Inbox]¶

[VB.NET Example - Retrieve email from “Deleted Items”]¶

Share

See Also