Retrieve Email from IMAP4 server in VB.NET

In previous section, I introduced retrieving email from POP3 server in VB.NET. In this section, I will introduce the IMAP4 server.

Introduction

IMAP4 protocol is different with POP3 protocol. First of all, IMAP4 supports retrieving email from different mail folder and folder management. Secondly, IMAP4 supports mail flags management. Therefore, we can do more things with IMAP4 server. To better understand the IMAP4 protocol, please see the following examples.

Note

Remarks: All of examples in this section are based on first section: A simple VB.NET project. To compile and run the following example codes successfully, please click here to learn how to create the test project and add reference to your project.

[VB.NET Example - Retrieve email from IMAP4 inbox]

The following example codes demonstrate how to download email from IMAP4 server default mailbox. In order to run it correctly, please change email server, user, password, folder, file name values.

Note

To get the full sample projects, please refer to Samples section.

Imports System.IO
Imports EAGetMail 'imports EAGetMail namespace

Module Module1
    Sub Main()

        ' Create a folder named "inbox" under current directory
        ' to save the email retrieved.
        Dim curpath As String = Directory.GetCurrentDirectory()
        Dim mailbox As String = [String].Format("{0}\inbox", curpath)

        ' If the folder is not existed, create it.
        If Not Directory.Exists(mailbox) Then
            Directory.CreateDirectory(mailbox)
        End If

        Dim oServer As New MailServer("imap4.emailarchitect.net", _
            "test@emailarchitect.net", "testpassword", ServerProtocol.Imap4)
        Dim oClient As New MailClient("TryIt")

        ' Set IMAP4 server port
        oServer.Port = 143

        ' If your IMAP4 server requires SSL connection,
        ' Please add the following codes:
        ' oServer.SSLConnection = True
        ' oServer.Port = 993

        Try
            oClient.Connect(oServer)
            Dim infos As MailInfo() = oClient.GetMailInfos()
            For i As Integer = 0 To infos.Length - 1
                Dim info As MailInfo = infos(i)
                Console.WriteLine("Index: {0}; Size: {1}; UIDL: {2}", _
                        info.Index, info.Size, info.UIDL)

                ' Receive email from IMAP4 server
                Dim oMail As Mail = oClient.GetMail(info)

                Console.WriteLine("From: {0}", oMail.From.ToString())
                Console.WriteLine("Subject: {0}" & vbCr & vbLf, oMail.Subject)

                ' Generate an email file name based on date time.
                Dim d As System.DateTime = System.DateTime.Now
                Dim cur As New System.Globalization.CultureInfo("en-US")
                Dim sdate As String = d.ToString("yyyyMMddHHmmss", cur)
                Dim fileName As String = [String].Format("{0}\{1}{2}{3}.eml", _
                    mailbox, sdate, d.Millisecond.ToString("d3"), i)

                ' Save email to local disk
                oMail.SaveAs(fileName, True)

                ' Mark email as deleted from IMAP server.
                oClient.Delete(info)
            Next

            ' Quit and purge emails marked as deleted from IMAP server.
            oClient.Quit()
        Catch ep As Exception
            Console.WriteLine(ep.Message)
        End Try

    End Sub
End Module

Because IMAP4 protocol supports folder access, so we can retrieve email from other mailbox rather than default “INBOX”. POP3 protocol doesn’t support this feature.

[VB.NET Example - Retrieve email from “Deleted Items”]

The following example codes demonstrate how to retrieve emails from “Deleted Items” in an IMAP4 account. In order to run it correctly, please change email server, user, password, folder, file name values.

Note

To get the full sample projects, please refer to Samples section.

Imports System.IO
Imports EAGetMail 'imports EAGetMail namespace

Module Module1
    Private Function SearchFolder(ByVal folders As Imap4Folder(), _
            ByVal name As String) As Imap4Folder
        Dim count As Integer = folders.Length
        For i As Integer = 0 To count - 1
            Dim folder As Imap4Folder = folders(i)
            Console.WriteLine(folder.FullPath)

            ' Folder was found.
            If [String].Compare(folder.Name, name) = 0 Then
                Return folder
            End If

            folder = SearchFolder(folder.SubFolders, name)
            If folder IsNot Nothing Then
                Return folder
            End If
        Next

        ' No folder found
        Return Nothing
    End Function

    Sub Main()

        ' Create a folder named "inbox" under current directory
        ' to save the email retrieved.
        Dim curpath As String = Directory.GetCurrentDirectory()
        Dim mailbox As String = [String].Format("{0}\inbox", curpath)

        ' If the folder is not existed, create it.
        If Not Directory.Exists(mailbox) Then
            Directory.CreateDirectory(mailbox)
        End If

        Dim oServer As New MailServer("imap4.emailarchitect.net", _
            "test@emailarchitect.net", "testpassword", ServerProtocol.Imap4)
        Dim oClient As New MailClient("TryIt")

        ' Set IMAP4 server port
        oServer.Port = 143

        ' If your IMAP4 server requires SSL connection,
        ' Please add the following codes:
        ' oServer.SSLConnection = True
        ' oServer.Port = 993

        Try
            oClient.Connect(oServer)

            ' Lookup folder based name.
            Dim folder As Imap4Folder = SearchFolder(oClient.Imap4Folders, "Deleted Items")
            If folder Is Nothing Then
                Throw New Exception("Folder was not found")
            End If

            ' Select this folder
            oClient.SelectFolder(folder)

            ' Retrieve emails from selected folder instead of default folder.
            Dim infos As MailInfo() = oClient.GetMailInfos()
            For i As Integer = 0 To infos.Length - 1
                Dim info As MailInfo = infos(i)
                Console.WriteLine("Index: {0}; Size: {1}; UIDL: {2}", _
                        info.Index, info.Size, info.UIDL)

                ' Receive email from IMAP4 server
                Dim oMail As Mail = oClient.GetMail(info)

                Console.WriteLine("From: {0}", oMail.From.ToString())
                Console.WriteLine("Subject: {0}" & vbCr & vbLf, oMail.Subject)

                ' Generate an email file name based on date time.
                Dim d As System.DateTime = System.DateTime.Now
                Dim cur As New System.Globalization.CultureInfo("en-US")
                Dim sdate As String = d.ToString("yyyyMMddHHmmss", cur)
                Dim fileName As String = [String].Format("{0}\{1}{2}{3}.eml", _
                    mailbox, sdate, d.Millisecond.ToString("d3"), i)

                ' Save email to local disk
                oMail.SaveAs(fileName, True)

                ' Mark email as deleted from IMAP server.
                oClient.Delete(info)
            Next

            ' Quit and purge emails marked as deleted from IMAP server.
            oClient.Quit()
        Catch ep As Exception
            Console.WriteLine(ep.Message)
        End Try

    End Sub
End Module

Next Section

At next section I will introduce how to retrieve email from Exchange Server with Web Service protocol.

Appendix

Comments

If you have any comments or questions about above example codes, please click here to add your comments.