VB.NET/ASP.NET/ASP MVC - Retrieve email using Microsoft OAuth 2.0 + IMAP4/Graph API protocol from Hotmail/Outlook account¶

Imports System
Imports System.IO
Imports System.Net
Imports System.Net.Sockets
Imports System.Threading
Imports System.Threading.Tasks
Imports System.Text
Imports System.Globalization
Imports System.Runtime.InteropServices
Imports EAGetMail

Module ModuleMsHotmail
    Sub Main(ByVal args As String())
        Console.WriteLine("+------------------------------------------------------------------+")
        Console.WriteLine("  Sign in with MS OAUTH                                             ")
        Console.WriteLine("   If you got ""This app isn't verified"" information in Web Browser, ")
        Console.WriteLine("   click ""Advanced"" -> Go to ... to continue test.")
        Console.WriteLine("+------------------------------------------------------------------+")
        Console.WriteLine("")
        Console.WriteLine("Press any key to sign in...")
        Console.ReadKey()

        Try
            Dim p As MsHotmailOauth = New MsHotmailOauth()
            p.DoOauthAndRetrieveEmail()
        Catch ep As Exception
            Console.WriteLine(ep.ToString())
        End Try

        Console.ReadKey()
    End Sub

    Public Class MsHotmailOauth
        Function _generateFileName(ByVal sequence As Integer) As String
            Dim currentDateTime As DateTime = DateTime.Now
            Return String.Format("{0}-{1:000}-{2:000}.eml",
                            currentDateTime.ToString("yyyyMMddHHmmss", New CultureInfo("en-US")),
                            currentDateTime.Millisecond,
                            sequence)
        End Function

        Private Sub RetrieveMailWithXOAUTH2(ByVal userEmail As String, ByVal accessToken As String)
            Try
                ' Create a folder named "inbox" under current directory
                ' to save the email retrieved.
                Dim localInbox As String = String.Format("{0}\inbox", Directory.GetCurrentDirectory())

                ' If the folder is not existed, create it.
                If Not Directory.Exists(localInbox) Then
                    Directory.CreateDirectory(localInbox)
                End If

                ' Hotmail/Outlook/Live IMAP4 Server address, use access token as password
                Dim oServer As New MailServer("outlook.office365.com",
                            userEmail,
                            accessToken,
                            ServerProtocol.Imap4)

                ' User OAUTH 2.0
                oServer.AuthType = ServerAuthType.AuthXOAUTH2
                ' Enable SSL/TLS connection,
                oServer.SSLConnection = True
                ' IMAP SSL Port
                oServer.Port = 993

                Console.WriteLine("Connecting {0} ...", oServer.Server)

                Dim oClient As New MailClient("TryIt")
                oClient.Connect(oServer)

                ' Get New email only, if you want to get all emails, please remove this line
                oClient.GetMailInfosParam.GetMailInfosOptions = GetMailInfosOptionType.NewOnly

                Dim infos As MailInfo() = oClient.GetMailInfos()
                Console.WriteLine("Total {0} email(s)", infos.Length)

                For i As Integer = 0 To infos.Length - 1
                    Dim info As MailInfo = infos(i)
                    Console.WriteLine("Index: {0}; Size: {1}; UIDL: {2}",
                            info.Index, info.Size, info.UIDL)

                    ' Retrieve email from email server
                    Dim oMail As Mail = oClient.GetMail(info)

                    Console.WriteLine("From: {0}", oMail.From.ToString())
                    Console.WriteLine("Subject: {0}" & vbCr & vbLf, oMail.Subject)

                    ' Generate an unqiue email file name based on date time.
                    Dim fileName As String = _generateFileName(i + 1)
                    Dim fullPath As String = String.Format("{0}\{1}", localInbox, fileName)

                    ' Save email to local disk
                    oMail.SaveAs(fullPath, True)

                    ' Mark email as read to prevent retrieving this email again.
                    oClient.MarkAsRead(info, True)

                    ' If you want to delete current email, please use Delete method instead of MarkAsRead
                    ' oClient.Delete(info)

                Next

                ' Quit and expunge emails marked as deleted from  server.
                oClient.Quit()
                Console.WriteLine("Completed!")

            Catch ep As Exception
                Console.WriteLine(ep.Message)
            End Try
        End Sub

        ' client configuration
        ' You should create your client id And client secret,
        ' do Not use the following client id in production environment, it Is used for test purpose only.
        Const clientID As String = "eccbabb2-3377-4265-85c1-ea2fb515f075"
        Const clientSecret As String = "QaR_RR:-5WqTY[nni9pdBr9xVybqrAu4"
        Const scope As String = "https://outlook.office.com/IMAP.AccessAsUser.All%20https://outlook.office.com/POP.AccessAsUser.All%20offline_access%20email%20openid"
        Const authUri As String = "https://login.microsoftonline.com/common/oauth2/v2.0/authorize"
        Const tokenUri As String = "https://login.microsoftonline.com/common/oauth2/v2.0/token"

        Private Shared Function GetRandomUnusedPort() As Integer
            Dim listener = New TcpListener(IPAddress.Loopback, 0)
            listener.Start()
            Dim port = (CType(listener.LocalEndpoint, IPEndPoint)).Port
            listener.[Stop]()
            Return port
        End Function

        Public Async Sub DoOauthAndRetrieveEmail()
            ' Creates a redirect URI using an available port on the loopback address.
            Dim redirectUri As String = String.Format("http://127.0.0.1:{0}/", GetRandomUnusedPort())
            Console.WriteLine("redirect URI: " & redirectUri)

            ' Creates an HttpListener to listen for requests on that redirect URI.
            Dim http = New HttpListener()
            http.Prefixes.Add(redirectUri)
            Console.WriteLine("Listening ...")
            http.Start()

            ' Creates the OAuth 2.0 authorization request.
            Dim authorizationRequest = String.Format("{0}?response_type=code&scope={1}&redirect_uri={2}&client_id={3}&prompt=login",
                                            authUri,
                                            scope,
                                            Uri.EscapeDataString(redirectUri),
                                            clientID)

            ' Opens request in the browser
            System.Diagnostics.Process.Start(authorizationRequest)

            ' Waits for the OAuth authorization response.
            Dim context = Await http.GetContextAsync()

            ' Brings the Console to Focus.
            BringConsoleToFront()

            ' Sends an HTTP response to the browser.
            Dim response = context.Response
            Dim responseString As String = String.Format("<html><head></head><body>Please return to the app and close current window.</body></html>")
            Dim buffer = Encoding.UTF8.GetBytes(responseString)
            response.ContentLength64 = buffer.Length
            Dim responseOutput = response.OutputStream
            Dim responseTask As Task = responseOutput.
                WriteAsync(buffer, 0, buffer.Length).
                ContinueWith(Sub(task)
                                responseOutput.Close()
                                http.[Stop]()
                                Console.WriteLine("HTTP server stopped.")
                            End Sub)

            ' Checks for errors.
            If context.Request.QueryString.[Get]("error") IsNot Nothing Then
                Console.WriteLine(String.Format("OAuth authorization error: {0}.", context.Request.QueryString.[Get]("error")))
                Return
            End If

            If context.Request.QueryString.[Get]("code") Is Nothing Then
                Console.WriteLine("Malformed authorization response. " & context.Request.RawUrl)
                Return
            End If

            ' extracts the authorization code
            Dim code = context.Request.QueryString.[Get]("code")
            Console.WriteLine("Authorization code: " & code)

            Dim responseText As String = Await RequestAccessToken(code, redirectUri)
            Console.WriteLine(responseText)

            Dim parser As OAuthResponseParser = New OAuthResponseParser()
            parser.Load(responseText)

            Dim user = parser.EmailInIdToken
            Dim accessToken = parser.AccessToken

            Console.WriteLine("User: {0}", user)
            Console.WriteLine("AccessToken: {0}", accessToken)

            RetrieveMailWithXOAUTH2(user, accessToken)
        End Sub

        Private Async Function RequestAccessToken(ByVal code As String, ByVal redirectUri As String) As Task(Of String)
            Console.WriteLine("Exchanging code for tokens...")

            ' builds the  request
            Dim tokenRequestBody = String.Format("code={0}&redirect_uri={1}&client_id={2}&grant_type=authorization_code",
                                            code,
                                            Uri.EscapeDataString(redirectUri),
                                            clientID)

            ' if your application is web application, add clientSecret parameter.
            ' Dim tokenRequestBody = String.Format("code={0}&redirect_uri={1}&client_id={2}&client_secret={3}&grant_type=authorization_code",
            '                code,
            '                Uri.EscapeDataString(redirectUri),
            '                clientID,
            '                clientSecret)

            ' sends the request
            Dim tokenRequest As HttpWebRequest = CType(WebRequest.Create(tokenUri), HttpWebRequest)
            tokenRequest.Method = "POST"
            tokenRequest.ContentType = "application/x-www-form-urlencoded"
            tokenRequest.Accept = "Accept=text/html,application/xhtml+xml,application/xml;q=0.9,*/*;q=0.8"

            Dim _byteVersion As Byte() = Encoding.ASCII.GetBytes(tokenRequestBody)
            tokenRequest.ContentLength = _byteVersion.Length
            Dim stream As Stream = tokenRequest.GetRequestStream()
            Await stream.WriteAsync(_byteVersion, 0, _byteVersion.Length)
            stream.Close()

            Try
                ' gets the response
                Dim tokenResponse As WebResponse = Await tokenRequest.GetResponseAsync()

                Using reader As StreamReader = New StreamReader(tokenResponse.GetResponseStream())
                    ' reads response body
                    Return Await reader.ReadToEndAsync()
                End Using

            Catch ex As WebException

                If ex.Status = WebExceptionStatus.ProtocolError Then
                    Dim response = TryCast(ex.Response, HttpWebResponse)

                    If response IsNot Nothing Then
                        Console.WriteLine("HTTP: " & response.StatusCode)

                        ' reads response body
                        Using reader As StreamReader = New StreamReader(response.GetResponseStream())
                            Dim responseText As String = reader.ReadToEnd()
                            Console.WriteLine(responseText)
                        End Using
                    End If
                End If

                Throw ex
            End Try
        End Function

        ' Hack to bring the Console window to front.
        Public Sub BringConsoleToFront()
            SetForegroundWindow(GetConsoleWindow())
        End Sub

        Private Declare Auto Function GetConsoleWindow Lib "kernel32.dll" () As IntPtr
        Private Declare Auto Function SetForegroundWindow Lib "user32.dll" (ByVal hWnd As IntPtr) As Int32

    End Class
End Module

Imports System
Imports System.IO
Imports System.Net
Imports System.Net.Sockets
Imports System.Threading
Imports System.Threading.Tasks
Imports System.Text
Imports System.Globalization
Imports System.Runtime.InteropServices
Imports EAGetMail

Module ModuleMsHotmail
    Sub Main(ByVal args As String())
        Console.WriteLine("+------------------------------------------------------------------+")
        Console.WriteLine("  Sign in with MS OAUTH                                             ")
        Console.WriteLine("   If you got ""This app isn't verified"" information in Web Browser, ")
        Console.WriteLine("   click ""Advanced"" -> Go to ... to continue test.")
        Console.WriteLine("+------------------------------------------------------------------+")
        Console.WriteLine("")
        Console.WriteLine("Press any key to sign in...")
        Console.ReadKey()

        Try
            Dim p As MsHotmailOauth = New MsHotmailOauth()
            p.DoOauthAndRetrieveEmail()
        Catch ep As Exception
            Console.WriteLine(ep.ToString())
        End Try

        Console.ReadKey()
    End Sub

    Public Class MsHotmailOauth
        Function _generateFileName(ByVal sequence As Integer) As String
            Dim currentDateTime As DateTime = DateTime.Now
            Return String.Format("{0}-{1:000}-{2:000}.eml",
                            currentDateTime.ToString("yyyyMMddHHmmss", New CultureInfo("en-US")),
                            currentDateTime.Millisecond,
                            sequence)
        End Function

        Private Sub RetrieveMailWithXOAUTH2(ByVal userEmail As String, ByVal accessToken As String)
            Try
                ' Create a folder named "inbox" under current directory
                ' to save the email retrieved.
                Dim localInbox As String = String.Format("{0}\inbox", Directory.GetCurrentDirectory())

                ' If the folder is not existed, create it.
                If Not Directory.Exists(localInbox) Then
                    Directory.CreateDirectory(localInbox)
                End If

                ' Hotmail/Outlook/Live Graph API Server address, use access token as password
                Dim oServer As New MailServer("graph.microsoft.com",
                            userEmail,
                            accessToken,
                            ServerProtocol.MsGraphApi)

                ' User OAUTH 2.0
                oServer.AuthType = ServerAuthType.AuthXOAUTH2
                ' Enable SSL/TLS connection,
                oServer.SSLConnection = True

                Console.WriteLine("Connecting {0} ...", oServer.Server)

                Dim oClient As New MailClient("TryIt")
                oClient.Connect(oServer)

                ' Get New email only, if you want to get all emails, please remove this line
                oClient.GetMailInfosParam.GetMailInfosOptions = GetMailInfosOptionType.NewOnly

                Dim infos As MailInfo() = oClient.GetMailInfos()
                Console.WriteLine("Total {0} email(s)", infos.Length)

                For i As Integer = 0 To infos.Length - 1
                    Dim info As MailInfo = infos(i)
                    Console.WriteLine("Index: {0}; Size: {1}; UIDL: {2}",
                            info.Index, info.Size, info.UIDL)

                    ' Retrieve email from email server
                    Dim oMail As Mail = oClient.GetMail(info)

                    Console.WriteLine("From: {0}", oMail.From.ToString())
                    Console.WriteLine("Subject: {0}" & vbCr & vbLf, oMail.Subject)

                    ' Generate an unqiue email file name based on date time.
                    Dim fileName As String = _generateFileName(i + 1)
                    Dim fullPath As String = String.Format("{0}\{1}", localInbox, fileName)

                    ' Save email to local disk
                    oMail.SaveAs(fullPath, True)

                    ' Mark email as read to prevent retrieving this email again.
                    oClient.MarkAsRead(info, True)

                    ' If you want to delete current email, please use Delete method instead of MarkAsRead
                    ' oClient.Delete(info)

                Next

                ' Quit and expunge emails marked as deleted from  server.
                oClient.Quit()
                Console.WriteLine("Completed!")

            Catch ep As Exception
                Console.WriteLine(ep.Message)
            End Try
        End Sub

        ' client configuration
        ' You should create your client id And client secret,
        ' do Not use the following client id in production environment, it Is used for test purpose only.
        Const clientID As String = "eccbabb2-3377-4265-85c1-ea2fb515f075"
        Const clientSecret As String = "QaR_RR:-5WqTY[nni9pdBr9xVybqrAu4"
        Const scope As String = "Mail.Send%20Mail.ReadWrite%20offline_access%20email%20openid"
        Const authUri As String = "https://login.microsoftonline.com/common/oauth2/v2.0/authorize"
        Const tokenUri As String = "https://login.microsoftonline.com/common/oauth2/v2.0/token"

        Private Shared Function GetRandomUnusedPort() As Integer
            Dim listener = New TcpListener(IPAddress.Loopback, 0)
            listener.Start()
            Dim port = (CType(listener.LocalEndpoint, IPEndPoint)).Port
            listener.[Stop]()
            Return port
        End Function

        Public Async Sub DoOauthAndRetrieveEmail()
            ' Creates a redirect URI using an available port on the loopback address.
            Dim redirectUri As String = String.Format("http://127.0.0.1:{0}/", GetRandomUnusedPort())
            Console.WriteLine("redirect URI: " & redirectUri)

            ' Creates an HttpListener to listen for requests on that redirect URI.
            Dim http = New HttpListener()
            http.Prefixes.Add(redirectUri)
            Console.WriteLine("Listening ...")
            http.Start()

            ' Creates the OAuth 2.0 authorization request.
            Dim authorizationRequest = String.Format("{0}?response_type=code&scope={1}&redirect_uri={2}&client_id={3}&prompt=login",
                                            authUri,
                                            scope,
                                            Uri.EscapeDataString(redirectUri),
                                            clientID)

            ' Opens request in the browser
            System.Diagnostics.Process.Start(authorizationRequest)

            ' Waits for the OAuth authorization response.
            Dim context = Await http.GetContextAsync()

            ' Brings the Console to Focus.
            BringConsoleToFront()

            ' Sends an HTTP response to the browser.
            Dim response = context.Response
            Dim responseString As String = String.Format("<html><head></head><body>Please return to the app and close current window.</body></html>")
            Dim buffer = Encoding.UTF8.GetBytes(responseString)
            response.ContentLength64 = buffer.Length
            Dim responseOutput = response.OutputStream
            Dim responseTask As Task = responseOutput.
                WriteAsync(buffer, 0, buffer.Length).
                ContinueWith(Sub(task)
                                responseOutput.Close()
                                http.[Stop]()
                                Console.WriteLine("HTTP server stopped.")
                            End Sub)

            ' Checks for errors.
            If context.Request.QueryString.[Get]("error") IsNot Nothing Then
                Console.WriteLine(String.Format("OAuth authorization error: {0}.", context.Request.QueryString.[Get]("error")))
                Return
            End If

            If context.Request.QueryString.[Get]("code") Is Nothing Then
                Console.WriteLine("Malformed authorization response. " & context.Request.RawUrl)
                Return
            End If

            ' extracts the authorization code
            Dim code = context.Request.QueryString.[Get]("code")
            Console.WriteLine("Authorization code: " & code)

            Dim responseText As String = Await RequestAccessToken(code, redirectUri)
            Console.WriteLine(responseText)

            Dim parser As OAuthResponseParser = New OAuthResponseParser()
            parser.Load(responseText)

            Dim user = parser.EmailInIdToken
            Dim accessToken = parser.AccessToken

            Console.WriteLine("User: {0}", user)
            Console.WriteLine("AccessToken: {0}", accessToken)

            RetrieveMailWithXOAUTH2(user, accessToken)
        End Sub

        Private Async Function RequestAccessToken(ByVal code As String, ByVal redirectUri As String) As Task(Of String)
            Console.WriteLine("Exchanging code for tokens...")

            ' builds the  request
            Dim tokenRequestBody = String.Format("code={0}&redirect_uri={1}&client_id={2}&grant_type=authorization_code",
                                            code,
                                            Uri.EscapeDataString(redirectUri),
                                            clientID)

            ' if your application is web application, add clientSecret parameter.
            ' Dim tokenRequestBody = String.Format("code={0}&redirect_uri={1}&client_id={2}&client_secret={3}&grant_type=authorization_code",
            '                code,
            '                Uri.EscapeDataString(redirectUri),
            '                clientID,
            '                clientSecret)

            ' sends the request
            Dim tokenRequest As HttpWebRequest = CType(WebRequest.Create(tokenUri), HttpWebRequest)
            tokenRequest.Method = "POST"
            tokenRequest.ContentType = "application/x-www-form-urlencoded"
            tokenRequest.Accept = "Accept=text/html,application/xhtml+xml,application/xml;q=0.9,*/*;q=0.8"

            Dim _byteVersion As Byte() = Encoding.ASCII.GetBytes(tokenRequestBody)
            tokenRequest.ContentLength = _byteVersion.Length
            Dim stream As Stream = tokenRequest.GetRequestStream()
            Await stream.WriteAsync(_byteVersion, 0, _byteVersion.Length)
            stream.Close()

            Try
                ' gets the response
                Dim tokenResponse As WebResponse = Await tokenRequest.GetResponseAsync()

                Using reader As StreamReader = New StreamReader(tokenResponse.GetResponseStream())
                    ' reads response body
                    Return Await reader.ReadToEndAsync()
                End Using

            Catch ex As WebException

                If ex.Status = WebExceptionStatus.ProtocolError Then
                    Dim response = TryCast(ex.Response, HttpWebResponse)

                    If response IsNot Nothing Then
                        Console.WriteLine("HTTP: " & response.StatusCode)

                        ' reads response body
                        Using reader As StreamReader = New StreamReader(response.GetResponseStream())
                            Dim responseText As String = reader.ReadToEnd()
                            Console.WriteLine(responseText)
                        End Using
                    End If
                End If

                Throw ex
            End Try
        End Function

        ' Hack to bring the Console window to front.
        Public Sub BringConsoleToFront()
            SetForegroundWindow(GetConsoleWindow())
        End Sub

        Private Declare Auto Function GetConsoleWindow Lib "kernel32.dll" () As IntPtr
        Private Declare Auto Function SetForegroundWindow Lib "user32.dll" (ByVal hWnd As IntPtr) As Int32

    End Class
End Module

' Please add http://localhost:54098/oauth/token to Authorized redirect URIs in your Google/MS Azure project.
Public Function Token(ByVal code As String) As ActionResult
    ' code parameter is the authorization code returned by Google/MS OAuth server,
    ' then you can use it to request AccessToken
    ' just like RequestAccessToken method in previous example
End Function