VB.NET - Retrieve email from Gmail account¶

The following vb.net example codes demonstrate how to retrieve email from Gmail IMAP4 server.

Gmail POP3 and IMAP4 Setting

Gmail POP3 server address is pop.gmail.com. It requires SSL connection on 995 port, and you should use your Gmail email address as the user name for user authentication.

Gmail IMAP4 server address is imap.gmail.com. It requires SSL connection on 993 port, and you should use your Gmail email address as the user name for user authentication. For example: your email is gmailid@gmail.com, and then the user name should be gmailid@gmail.com.

To retrieve email from Gmail account, you need to enable POP3 or IMAP4 access in your gmail account settings.

Because Gmail POP3 server doesn’t work like normal POP3 server, it hides old emails automatically even the email was not deleted, so we suggest that you use IMAP4 protocol.

Server	Port	SSL	Protocol
pop.gmail.com	995	SSL required	Pop3
imap.gmail.com	993	SSL required	Imap4 (recommended)

Gmail App Password¶

To help keep your account secure, starting May 30, 2022, Google will no longer support the use of third-party apps or devices which ask you to sign in to your Google Account using only your username and password.

Therefore, you should sign in using App Passwords. An App Password is a 16-digit passcode that gives a less secure app or device permission to access your Google Account. App Passwords can only be used with accounts that have 2-Step Verification turned on. You need to use App Password instead of the user password for user authentication.

Another solution is Gmail OAUH, please see Gmail IMAP OAUTH section.

Installation¶

Before you can use the following sample codes, you should download the EAGetMail Installer and install it on your machine at first. Full sample projects are included in this installer.

Install from NuGet

You can also install the run-time assembly by NuGet. Run the following command in the NuGet Package Manager Console:

Install-Package EAGetMail

Note

If you install it by NuGet, no sample projects are installed, only .NET assembly is installed.

Add reference¶

To use EAGetMail POP3 & IMAP Component in your project, the first step is “Add reference of EAGetMail to your project”. Please create or open your project with Visual Studio, then go to menu -> Project -> Add Reference -> .NET -> Browse..., and select Installation path\Lib\[netversion]\EAGetMail.dll, click Open-> OK, the reference will be added to the project, you can start to use it to retrieve email and parse email in your project.

.NET assembly¶

Because EAGetMail has separate builds for .Net Framework, please refer to the following table and choose the correct dll.

Separate builds of run-time assembly for .Net Framework 2.0, 4.0, 4.5, 4.6.1, 4.7.2, 4.8.1, .NET 6.0, NET 7.0, .NET 8.0, .NET Standard 2.0 and .Net Compact Framework 2.0, 3.5.

File	.NET Framework Version
Lib\[net20\|40\|45\|461\|472\|481]\EAGetMail.dll	Built with .NET Framework 2.0, 4.0, 4.5, 4.6.1, 4.7.2, 4.8.1 It requires .NET Framework 2.0, 3.5 or later version.
Lib\[net5.0\|6.0\|7.0\|8.0]\EAGetMail.dll	Built with .NET 5.0, .NET 6.0, .NET 7.0, .NET 8.0 It requires .NET 5.0 or later version.
Lib\netstandard2.0\EAGetMail.dll	Built with .NET Standard 2.0 It requires .NET Standard 2.0 or later version.
Lib\[net20-cf\|net35-cf]\EAGetMail.dll	Built with .NET Compact Framework 2.0, 3.5 It requires .NET Compact Framework 2.0, 3.5 or later version.

VB.NET - Retrieve email from Gmail account - example¶

The following example codes demonstrate how to use EAGetMail POP3 component to download email from Gmail IMAP server. In order to run it correctly, please change email server, user, password, folder, file name value to yours.

Note

To get full sample projects, please download and install EAGetMail on your machine.

Because Gmail POP3 server doesn’t work like normal POP3 server, it hides old emails automatically even the email was not deleted, so we suggest that you use IMAP4 protocol.

IImports System.Globalization
Imports System.Text
Imports System.IO
Imports EAGetMail 'imports EAGetMail namespace

Module Module1

    Function _generateFileName(ByVal sequence As Integer) As String
        Dim currentDateTime As DateTime = DateTime.Now
        Return String.Format("{0}-{1:000}-{2:000}.eml",
                            currentDateTime.ToString("yyyyMMddHHmmss", New CultureInfo("en-US")),
                            currentDateTime.Millisecond,
                            sequence)
    End Function

    Sub Main()

        Try
            ' Create a folder named "inbox" under current directory
            ' to save the email retrieved.
            Dim localInbox As String = String.Format("{0}\inbox", Directory.GetCurrentDirectory())

            ' If the folder is not existed, create it.
            If Not Directory.Exists(localInbox) Then
                Directory.CreateDirectory(localInbox)
            End If

            ' Create app password in Google account
            ' https://support.google.com/accounts/answer/185833?hl=en
            ' Gmail IMAP server is "imap.gmail.com"
            Dim oServer As New MailServer("imap.gmail.com",
                    "gmailid@gmail.com",
                    "your app password",
                    ServerProtocol.Imap4)

            ' Enable SSL/TLS connection, most modern email server require SSL/TLS connection by default.
            oServer.SSLConnection = True
            ' Set 993 IMAP SSL Port
            oServer.Port = 993

            Console.WriteLine("Connecting server ...")

            Dim oClient As New MailClient("TryIt")
            oClient.Connect(oServer)

            Dim infos As MailInfo() = oClient.GetMailInfos()
            Console.WriteLine("Total {0} email(s)", infos.Length)

            For i As Integer = 0 To infos.Length - 1
                Dim info As MailInfo = infos(i)
                Console.WriteLine("Index: {0}; Size: {1}; UIDL: {2}",
                        info.Index, info.Size, info.UIDL)

                ' Retrieve email from IMAP server
                Dim oMail As Mail = oClient.GetMail(info)

                Console.WriteLine("From: {0}", oMail.From.ToString())
                Console.WriteLine("Subject: {0}" & vbCr & vbLf, oMail.Subject)

                ' Generate an unqiue email file name based on date time.
                Dim fileName As String = _generateFileName(i + 1)
                Dim fullPath As String = String.Format("{0}\{1}", localInbox, fileName)

                ' Save email to local disk
                oMail.SaveAs(fullPath, True)

                ' Mark email as deleted from IMAP server.
                oClient.Delete(info)

            Next

            ' Quit and expunge emails marked as deleted from IMAP server.
            oClient.Quit()
            Console.WriteLine("Completed!")

        Catch ep As Exception
            Console.WriteLine(ep.Message)
        End Try

    End Sub
End Module

Gmail IMAP OAUTH¶

By default, you can generate an App Passwords, and use this app password instead of the user password for IMAP4 authentication.

However, Google will disable traditional user authentication in the future, switching to Google OAuth is strongly recommended now.

VB.NET - Retrieve unread/new email from Gmail account - example¶

Because IMAP/EWS/WebDAV support read mail flag, with this feature, we can also retrieve unread/new email only from Gmail like this

Imports System.Globalization
Imports System.Text
Imports System.IO
Imports EAGetMail 'imports EAGetMail namespace

Module Module1

    Function _generateFileName(ByVal sequence As Integer) As String
        Dim currentDateTime As DateTime = DateTime.Now
        Return String.Format("{0}-{1:000}-{2:000}.eml",
                            currentDateTime.ToString("yyyyMMddHHmmss", New CultureInfo("en-US")),
                            currentDateTime.Millisecond,
                            sequence)
    End Function

    Sub Main()

        Try
            ' Create a folder named "inbox" under current directory
            ' to save the email retrieved.
            Dim localInbox As String = String.Format("{0}\inbox", Directory.GetCurrentDirectory())

            ' If the folder is not existed, create it.
            If Not Directory.Exists(localInbox) Then
                Directory.CreateDirectory(localInbox)
            End If

            ' Create app password in Google account
            ' https://support.google.com/accounts/answer/185833?hl=en
            ' Gmail IMAP server is "imap.gmail.com"
            Dim oServer As New MailServer("imap.gmail.com",
                    "gmailid@gmail.com",
                    "your app password",
                    ServerProtocol.Imap4)

            ' Enable SSL/TLS connection, most modern email server require SSL/TLS connection by default.
            oServer.SSLConnection = True
            ' Set 993 IMAP SSL Port
            oServer.Port = 993

            Console.WriteLine("Connecting server ...")

            Dim oClient As New MailClient("TryIt")
            oClient.Connect(oServer)

            ' retrieve unread/new email only
            oClient.GetMailInfosParam.Reset()
            oClient.GetMailInfosParam.GetMailInfosOptions = GetMailInfosOptionType.NewOnly

            Dim infos As MailInfo() = oClient.GetMailInfos()
            Console.WriteLine("Total {0} unread email(s)", infos.Length)

            For i As Integer = 0 To infos.Length - 1
                Dim info As MailInfo = infos(i)
                Console.WriteLine("Index: {0}; Size: {1}; UIDL: {2}",
                        info.Index, info.Size, info.UIDL)

                ' Retrieve email from IMAP server
                Dim oMail As Mail = oClient.GetMail(info)

                Console.WriteLine("From: {0}", oMail.From.ToString())
                Console.WriteLine("Subject: {0}" & vbCr & vbLf, oMail.Subject)

                ' Generate an unqiue email file name based on date time.
                Dim fileName As String = _generateFileName(i + 1)
                Dim fullPath As String = String.Format("{0}\{1}", localInbox, fileName)

                ' Save email to local disk
                oMail.SaveAs(fullPath, True)

                ' mark unread email as read, next time this email won't be retrieved again
                If Not info.Read Then
                    oClient.MarkAsRead(info, True)
                End If

                ' if you don't want to leave a copy on server, please use
                ' oClient.Delete(info)
                ' instead of MarkAsRead

            Next

            ' Quit and expunge emails marked as deleted from IMAP server.
            oClient.Quit()
            Console.WriteLine("Completed!")

        Catch ep As Exception
            Console.WriteLine(ep.Message)
        End Try

    End Sub
End Module

TLS 1.2 protocol¶

TLS is the successor of SSL, more and more SMTP servers require TLS 1.2 encryption now.

If your operating system is Windows XP/Vista/Windows 7/Windows 2003/2008/2008 R2/2012/2012 R2, you need to enable TLS 1.2 protocol in your operating system like this:

Enable TLS 1.2 on Windows XP/Vista/7/10/Windows 2008/2008 R2/2012

Tutorial Index