VB.NET/ASP.NET/ASP MVC - Retrieve email using Gmail/G Suite OAuth 2.0 + IMAP4 protocol in background service (service account)¶

' You can install Google.Apis.Auth.OAuth2 by NuGet
' Install-Package Google.Apis.Auth
Imports  System
Imports  System.IO
Imports  System.Net
Imports  System.Net.Sockets
Imports  System.Text
Imports  System.Threading
Imports  System.Threading.Tasks
Imports  System.Security.Cryptography.X509Certificates
Imports  System.Runtime.InteropServices
Imports  Google.Apis.Auth.OAuth2
Imports  EAGetMail
Imports  System.Globalization

Function _generateFileName(ByVal sequence As Integer) As String
    Dim currentDateTime As DateTime = DateTime.Now
    Return String.Format("{0}-{1:000}-{2:000}.eml",
                    currentDateTime.ToString("yyyyMMddHHmmss", New CultureInfo("en-US")),
                    currentDateTime.Millisecond,
                    sequence)
End Function

Public Sub RetrieveEmail()
    Try
        ' service account email address
        Const serviceAccount As String = "xxxxxx@xxxxx.iam.gserviceaccount.com"

        ' import service account key p12 certificate.
        Dim certificate = New X509Certificate2("D:\MyData\myoauth-77dec4d192ec.p12", "notasecret", X509KeyStorageFlags.Exportable)

        ' G Suite user email address
        Dim gsuiteUser = "user@gsuitdomain.com"

        Dim serviceAccountCredentialInitializer = New ServiceAccountCredential.Initializer(serviceAccount) With {
            .User = gsuiteUser,
            .Scopes = {"https://mail.google.com/"}
        }.FromCertificate(certificate)

        ' if service account key is in json format, copy the private key from json file:
        ' "private_key": "-----BEGIN PRIVATE KEY-----\n...\n-----END PRIVATE KEY-----\n"
        ' and import it like this:

        ' Dim privateKey As String = "-----BEGIN PRIVATE KEY-----" & vbLf & "MIIEv...revdd" & vbLf & "-----END PRIVATE KEY-----" & vbLf
        ' Dim serviceAccountCredentialInitializer = New ServiceAccountCredential.Initializer(serviceAccount) With {
        '    .User = gsuiteUser,
        '    .Scopes = {"https://mail.google.com/"}
        ' }.FromPrivateKey(privateKey)

        ' request access token
        Dim credential = New ServiceAccountCredential(serviceAccountCredentialInitializer)
        If Not credential.RequestAccessTokenAsync(CancellationToken.None).Result Then
            Throw New InvalidOperationException("Access token failed.")
        End If

        ' Create a folder named "inbox" under current directory
        ' to save the email retrieved.
        Dim localInbox As String = String.Format("{0}\inbox", Directory.GetCurrentDirectory())

        ' If the folder is not existed, create it.
        If Not Directory.Exists(localInbox) Then
            Directory.CreateDirectory(localInbox)
        End If

        ' Gmail IMAP4 Server address, use access token as password
        Dim oServer As New MailServer("imap.gmail.com",
                    gsuiteUser,
                    credential.Token.AccessToken,
                    ServerProtocol.Imap4)

        ' User OAUTH 2.0
        oServer.AuthType = ServerAuthType.AuthXOAUTH2
        ' Enable SSL/TLS connection,
        oServer.SSLConnection = True
        ' IMAP SSL Port
        oServer.Port = 993

        ' Since EAGetMail 5.3.5, Gmail Rest API is supported as well. You can use the following code
        ' to retrieve email using Gmail Rest API.
        ' Dim oServer As New MailServer("gmail.googleapis.com",
        '        userEmail,
        '        accessToken,
        '        ServerProtocol.GmailRestApi)

        ' oServer.AuthType = ServerAuthType.AuthXOAUTH2
        ' oServer.SSLConnection = True

        Console.WriteLine("Connecting {0} ...", oServer.Server)

        Dim oClient As New MailClient("TryIt")
        oClient.Connect(oServer)

        ' Get New email only, if you want to get all emails, please remove this line
        oClient.GetMailInfosParam.GetMailInfosOptions = GetMailInfosOptionType.NewOnly

        Dim infos As MailInfo() = oClient.GetMailInfos()
        Console.WriteLine("Total {0} email(s)", infos.Length)

        For i As Integer = 0 To infos.Length - 1
            Dim info As MailInfo = infos(i)
            Console.WriteLine("Index: {0}; Size: {1}; UIDL: {2}",
                    info.Index, info.Size, info.UIDL)

            ' Retrieve email from email server
            Dim oMail As Mail = oClient.GetMail(info)

            Console.WriteLine("From: {0}", oMail.From.ToString())
            Console.WriteLine("Subject: {0}" & vbCr & vbLf, oMail.Subject)

            ' Generate an unqiue email file name based on date time.
            Dim fileName As String = _generateFileName(i + 1)
            Dim fullPath As String = String.Format("{0}\{1}", localInbox, fileName)

            ' Save email to local disk
            oMail.SaveAs(fullPath, True)

            ' Mark email as read to prevent retrieving this email again.
            oClient.MarkAsRead(info, True)

            ' If you want to delete current email, please use Delete method instead of MarkAsRead
            ' oClient.Delete(info)

        Next

        ' Quit and expunge emails marked as deleted from  server.
        oClient.Quit()
        Console.WriteLine("Completed!")

    Catch ep As Exception
        Console.WriteLine(ep.ToString())
    End Try
End Sub