VB6 - Email queue with EASendMail Service - database¶

oMail.Headers.ReplaceHeader("X-Data-Connection", _
     "Driver={Microsoft Access Driver (*.mdb, *.accdb)}; " & _
     "Dbq=c:\easendmail\easendmail_demo.mdb;Uid=;Pwd=;")

Const ConnectNormal = 0
Const ConnectSSLAuto = 1
Const ConnectSTARTTLS = 2
Const ConnectDirectSSL = 3
Const ConnectTryTLS = 4

Private Sub btnSendMail_Click()

    Dim oSmtp As New EASendMailObjLib.Mail
    oSmtp.LicenseCode = "TryIt"

    ' Set your sender email address
    oSmtp.FromAddr = "test@emailarchitect.net"

    ' Set email subject
    oSmtp.subject = "simple email from VB 6.0 database queue"

    ' If you want to EASendMail service send the email after 10 minutes, please use the following code.
    ' oSmtp.Date = DateAdd("n", 10, Now())

    ' EASendMail will use the following connection to connect to the database,
    ' the syntax is same as ADO connection object.
    oSmtp.AddHeader "X-Data-Connection", _
    "Driver={Microsoft Access Driver (*.mdb)};Dbq={$var_easendmailpath}\easendmail_demo.mdb;Uid=;Pwd=;"

    ' EASendMail will select the fields by the following sql statement
    ' before sending email,
    ' then pick the recipient address from specified field.
    oSmtp.AddHeader "X-Sql-Select", "SELECT id, name, address FROM Recipients"

    ' Pick "name" field as the recipient name and "address" field as the recipient address.
    ' You can also use {$var_srecord:fieldname} to pick any field in X-Sql-Select statement
    ' and put it to subject, bodytext, then EASendMail will replace it automatially.
    oSmtp.DisplayTo = """{$var_srecord:name}"" <{$var_srecord:address}>"
    oSmtp.AddHeader "X-Rcpt-To", "{$var_srecord:address}"

    ' EASendMail service will execute the following sql statement on
    ' every email was sent successfully.
    oSmtp.AddHeader "X-Sql-OnSentSuccess", _
    "INSERT INTO sentlog ( server, email ) VALUES( '{$var_server}', '{$var_rcptaddr}' )"

    ' EASendMail service will execute the following sql statement on
    ' every email could not be sent.
    oSmtp.AddHeader "X-Sql-OnSentError", _
    "INSERT INTO errorlog( email, server, errorcode, errordescription ) " & _
    "VALUES( '{$var_rcptaddr}', '{$var_server}', '{$var_errcode}', '{$var_errdesc}' )"

    Dim bodytext As String

    bodytext = "Hi {$var_srecord:name}, " & Chr(13) & Chr(10)
    bodytext = bodytext & "Send email with queue." & Chr(13) & Chr(10) & Chr(13) & Chr(10)
    bodytext = bodytext & "From:Tester" & Chr(13) & Chr(10)
    ' {$var_srecord:address} will be replaced by EASendMail automatically.
    bodytext = bodytext & "To:{$var_srecord:address}" & Chr(13) & Chr(10) & Chr(13) & Chr(10)
    bodytext = bodytext & "Your id in database is {$var_srecord:id}." & Chr(13) & Chr(10)

    oSmtp.bodytext = bodytext

    ' Your SMTP server address
    oSmtp.ServerAddr = "smtp.emailarchitect.net"

    ' User and password for ESMTP authentication, if your server doesn't require
    ' User authentication, please remove the following codes.
    oSmtp.UserName = "test@emailarchitect.net"
    oSmtp.Password = "testpassword"

    ' ConnectTryTLS means if server supports SSL/TLS connection, SSL/TLS is used automatically
    oSmtp.ConnectType = ConnectTryTLS

    ' If your server uses 587 port
    ' oSmtp.ServerPort = 587

    ' If your server uses 25/587/465 port with SSL/TLS
    ' oSmtp.ConnectType = ConnectSSLAuto
    ' oSmtp.ServerPort = 25 ' 25 or 587 or 465

    MsgBox "start to send email ..."

    If oSmtp.SendMailToQueue() = 0 Then
        MsgBox "email was sent to queue successfully!"
    Else
        MsgBox "failed to send email with the following error:" & oSmtp.GetLastErrDescription()
    End If

End Sub