VB6 - Retrieve email from Gmail account¶

The following vb6 example codes demonstrate how to retrieve email from Gmail IMAP4 server.

Gmail POP3 and IMAP4 Setting

Gmail POP3 server address is pop.gmail.com. It requires SSL connection on 995 port, and you should use your Gmail email address as the user name for user authentication.

Gmail IMAP4 server address is imap.gmail.com. It requires SSL connection on 993 port, and you should use your Gmail email address as the user name for user authentication. For example: your email is gmailid@gmail.com, and then the user name should be gmailid@gmail.com.

To retrieve email from Gmail account, you need to enable POP3 or IMAP4 access in your gmail account settings.

Because Gmail POP3 server doesn’t work like normal POP3 server, it hides old emails automatically even the email was not deleted, so we suggest that you use IMAP4 protocol.

Server	Port	SSL	Protocol
pop.gmail.com	995	SSL required	Pop3
imap.gmail.com	993	SSL required	Imap4 (recommended)

Gmail App Password¶

To help keep your account secure, starting May 30, 2022, Google will no longer support the use of third-party apps or devices which ask you to sign in to your Google Account using only your username and password.

Therefore, you should sign in using App Passwords. An App Password is a 16-digit passcode that gives a less secure app or device permission to access your Google Account. App Passwords can only be used with accounts that have 2-Step Verification turned on. You need to use App Password instead of the user password for user authentication.

Another solution is Gmail OAUH, please see Gmail IMAP OAUTH section.

Last update: Google has disabled App password, you have to switch to Gmail IMAP OAUTH. If you don’t want to change your code, you can have a try with EA Oauth Service.

Installation¶

Before you can use the following sample codes, you should download the EAGetMail Installer and install it on your machine at first. Full sample projects are included in this installer.

Add reference¶

To use EAGetMail POP3 & IMAP4 ActiveX Object in your project, the first step is Add reference of EAGetMail to your project. Please go to menu -> Project -> References -> and select EAGetMailObj ActiveX Object, click OK, the reference will be added to your project, and you can start to use it to retrieve email and parse email in your project.

Add reference in VBA (EXCEL/Access/Outlook)¶

Open VBA IDE by press Alt+F11, Please select menu -> Tools -> References -> and select EASendMailObj ActiveX Object, click OK, the reference will be added to current VBA project, and you can start to use it to retrieve email and parse email in your VBA project.

To better demonstrate how to retrieve email and parse email, let’s create a VB 6.0 Standard EXE project at first, then add a CommandButton on the Form, double-click this button. It is like this

VB6 - Retrieve email from Gmail account - example¶

The following example codes demonstrate how to use EAGetMail POP3 component to download email from Gmail IMAP server. In order to run it correctly, please change email server, user, password, folder, file name value to yours.

Note

To get full sample projects, please download and install EAGetMail on your machine.

Because Gmail POP3 server doesn’t work like normal POP3 server, it hides old emails automatically even the email was not deleted, so we suggest that you use IMAP4 protocol.

Option Explicit

Const MailServerPop3 = 0
Const MailServerImap4 = 1
Const MailServerEWS = 2
Const MailServerDAV = 3
Const MailServerMsGraph = 4

Private Sub Command1_Click()
    Dim curpath As String
    Dim mailbox As String
    Dim oTools As New EAGetMailObjLib.Tools

    ' Create a folder named "inbox" under current directory
    ' to save the email retrieved.
    curpath = App.Path
    mailbox = curpath & "\inbox"
    oTools.CreateFolder mailbox

    Dim oServer As New EAGetMailObjLib.MailServer
    ' Gmail IMAP server address
    oServer.Server = "imap.gmail.com"
    oServer.User = "gmailid@gmail.com"

    ' Create app password in Google account
    ' https://support.google.com/accounts/answer/185833?hl=en
    oServer.Password = "your app password"
    oServer.Protocol = MailServerImap4

    ' Enable SSL Connection
    oServer.SSLConnection = True

    ' Set 993 SSL Port
    oServer.Port = 993

On Error GoTo ErrorHandle:
    Dim oClient As New EAGetMailObjLib.MailClient
    oClient.LicenseCode = "TryIt"

    oClient.Connect oServer
    MsgBox "Connected"

    Dim infos As EAGetMailObjLib.MailInfoCollection
    Set infos = oClient.GetMailInfoList()
    MsgBox infos.Count & " emails"

    Dim i As Long
    For i = 0 To infos.Count - 1
        Dim info As EAGetMailObjLib.MailInfo
        Set info = infos.Item(i)

        MsgBox "Index: " & info.Index & "; Size: " & info.Size & _
        "; UIDL: " & info.UIDL

        ' Receive email from Gmail server
        Dim oMail As EAGetMailObjLib.Mail
        Set oMail = oClient.GetMail(info)

        MsgBox "From: " & oMail.From.Address & _
            vbCrLf & "Subject: " & oMail.Subject

        Dim fileName As String
        ' Generate a random file name by current local datetime,
        ' You can use your method to generate the filename if you do not like it
        fileName = mailbox & "\" & oTools.GenFileName(i) & ".eml"

        ' Save email to local disk
        oMail.SaveAs fileName, True

        ' Mark email as deleted from Gmail server.
        oClient.Delete info
    Next

    ' Quit and expunge emails marked as deleted from Gmail server.
    oClient.Quit
    Exit Sub

ErrorHandle:
    MsgBox Err.Description
End Sub

Gmail IMAP OAUTH¶

By default, you can generate an App Passwords, and use this app password instead of the user password for IMAP4 authentication.

However, Google will disable traditional user authentication in the future, switching to Google OAuth is strongly recommended now.

VB6 - Retrieve unread/new email from Gmail account - example¶

Because IMAP/EWS/WebDAV support read mail flag, with this feature, we can also retrieve unread/new email only from Gmail like this

Option Explicit

Const MailServerPop3 = 0
Const MailServerImap4 = 1
Const MailServerEWS = 2
Const MailServerDAV = 3
Const MailServerMsGraph = 4

Const GetMailInfos_All = 1
Const GetMailInfos_NewOnly = 2
Const GetMailInfos_ReadOnly = 4
Const GetMailInfos_SeqRange = 8
Const GetMailInfos_UIDRange = 16
Const GetMailInfos_PR_ENTRYID = 32
Const GetMailInfos_DateRange = 64
Const GetMailInfos_OrderByDateTime = 128

Private Sub Command1_Click()
    Dim curpath As String
    Dim mailbox As String
    Dim oTools As New EAGetMailObjLib.Tools

    ' Create a folder named "inbox" under current directory
    ' to save the email retrieved.
    curpath = App.Path
    mailbox = curpath & "\inbox"
    oTools.CreateFolder mailbox

    Dim oServer As New EAGetMailObjLib.MailServer
    ' Gmail IMAP server address
    oServer.Server = "imap.gmail.com"
    oServer.User = "gmailid@gmail.com"

    ' Create app password in Google account
    ' https://support.google.com/accounts/answer/185833?hl=en
    oServer.Password = "your app password"
    oServer.Protocol = MailServerImap4

    ' Enable SSL Connection
    oServer.SSLConnection = True

    ' Set 993 SSL Port
    oServer.Port = 993

On Error GoTo ErrorHandle:
    Dim oClient As New EAGetMailObjLib.MailClient
    oClient.LicenseCode = "TryIt"

    oClient.Connect oServer
    MsgBox "Connected"

    ' retrieve unread/new email only
    oClient.GetMailInfosParam.Reset
    oClient.GetMailInfosParam.GetMailInfosOptions = GetMailInfos_NewOnly

    Dim infos As EAGetMailObjLib.MailInfoCollection
    Set infos = oClient.GetMailInfoList()
    MsgBox infos.Count & " unread emails"

    Dim i As Long
    For i = 0 To infos.Count - 1
        Dim info As EAGetMailObjLib.MailInfo
        Set info = infos.Item(i)

        MsgBox "Index: " & info.Index & "; Size: " & info.Size & _
        "; UIDL: " & info.UIDL

        ' Receive email from Gmail server
        Dim oMail As EAGetMailObjLib.Mail
        Set oMail = oClient.GetMail(info)

        MsgBox "From: " & oMail.From.Address & _
            vbCrLf & "Subject: " & oMail.Subject

        Dim fileName As String
        ' Generate a random file name by current local datetime,
        ' You can use your method to generate the filename if you do not like it
        fileName = mailbox & "\" & oTools.GenFileName(i) & ".eml"

        ' Save email to local disk
        oMail.SaveAs fileName, True

        ' mark unread email as read, next time this email won't be retrieved again
        If Not info.Read Then
            oClient.MarkAsRead info, True
        End If

        ' if you don't want to leave a copy on server, please use
        ' oClient.Delete info
        ' instead of MarkAsRead
    Next

    ' Quit and expunge emails marked as deleted from Gmail server.
    oClient.Quit
    Exit Sub

ErrorHandle:
    MsgBox Err.Description
End Sub

TLS 1.2 protocol¶

TLS is the successor of SSL, more and more SMTP servers require TLS 1.2 encryption now.

If your operating system is Windows XP/Vista/Windows 7/Windows 2003/2008/2008 R2/2012/2012 R2, you need to enable TLS 1.2 protocol in your operating system like this:

Enable TLS 1.2 on Windows XP/Vista/7/10/Windows 2008/2008 R2/2012

32bit/x64 ActiveX DLL¶

Seperate builds of run-time dll for 32 and x64 platform

File	Platform
Installation Path\Lib\native\x86\EAGetMailObj.dll	32 bit
Installation Path\Lib\native\x64\EAGetMailObj.dll	64 bit

Distribution¶

Standard EXE

For VB6, C++, Delphi or other standard exe application, you can distribute EAGetMailObj.dll with your application to target machine without COM-registration and installer. To learn more detail, please have a look at Registration-free COM with Manifest File.
Script

For ASP, VBScript, VBA, MS SQL Stored Procedure, you need to install EAGetMail on target machine by EAGetMail installer, both 32bit/x64 DLL are installed and registered.

Tutorial Index