Encrypt Email in VB.NET - S/MIME with RC2, 3DES and RSAES-OAEP

In previous section, I introduced how to send email with digital signature. In this section, I will introduce how to encrypt email with digital certificate in VB.NET.

Introduction

After the recipient received your email with digital signature, the recipient can get your digital certificate public key from your digital signature. Then the recipient can encrypt an email with your public key and send it to you. Only you can decrypt this email with your private key. That is how S/MIME can protect your email content. If you don’t expose your digital certificate private key to others, none can read your email which is encrypted by your public key.

If you received an email with digital signature, your email client usually stores the public key of the sender in “Control Panel” -> “Internet Options” -> “Content” -> “Certificates” -> “Other People”.

Then you can use the following code to encrypt email and send it to your recipient.

Note

Remarks: All of samples in this section are based on first section: Send email in a simple VB.NET project. To compile and run the following example codes successfully, please click here to learn how to create the test project and add reference of EASendMail to your project.

[VB.NET - Encrypt Email (S/MIME) - Example]

The following example codes demonstrate how to encrypt email with digital certificate in VB.NET.

Note

To get the full sample projects, please refer to Samples section.

Imports EASendMail 'Add EASendMail namespace
Module Module1
    Sub Main()
        Dim oMail As New SmtpMail("TryIt")
        Dim oSmtp As New SmtpClient()
        ' Set sender email address, please change it to yours
        oMail.From = "test@emailarchitect.net"

        ' Set recipient email address, please change it to yours
        oMail.To = "support@emailarchitect.net"

        ' Set email subject
        oMail.Subject = "test encrypted email"

        ' Set email body
        oMail.TextBody = "this is a test email with email encryption (S/MIME)"

        ' Your SMTP server address
        Dim oServer As New SmtpServer("smtp.emailarchitect.net")

        ' User and password for ESMTP authentication, if your server doesn't require
        ' User authentication, please remove the following codes.
        oServer.User = "test@emailarchitect.net"
        oServer.Password = "testpassword"

        ' If your SMTP server requires SSL/TLS connection, please add this line
        ' oServer.ConnectType = SmtpConnectType.ConnectSSLAuto

        Try
            ' Find certificate by email adddress in My Personal Store.
            ' Once the certificate is loaded to From, the email content
            ' will be signed automatically
            oMail.From.Certificate.FindSubject(oMail.From.Address, _
                Certificate.CertificateStoreLocation.CERT_SYSTEM_STORE_CURRENT_USER, _
                "My")
        Catch exp As Exception
            Console.WriteLine("No sign certificate found for <" + _
                oMail.From.Address + ">:" + exp.Message)
        End Try

       Dim count As Integer = oMail.To.Count
        For i As Integer = 0 To count - 1
            Dim oAddress As MailAddress = oMail.To(i)
            Try
                ' Find certificate by email adddress in My Other Peoples Store.
                ' The certificate can be also imported by *.cer file like this:
                ' oAddress.Certificate.Load("c:\encrypt1.cer")
                ' Once the certificate is loaded to MailAddress, the email content
                ' will be encrypted automatically
                oAddress.Certificate.FindSubject(oAddress.Address, _
                    Certificate.CertificateStoreLocation.CERT_SYSTEM_STORE_CURRENT_USER, _
                    "AddressBook")
            Catch ep As Exception
                Try
                    oAddress.Certificate.FindSubject(oAddress.Address, _
                        Certificate.CertificateStoreLocation.CERT_SYSTEM_STORE_CURRENT_USER, _
                        "My")
                Catch exp As Exception
                    Console.WriteLine("No encryption certificate found for <" + _
                         oAddress.Address + ">:" + exp.Message)
                End Try
            End Try
        Next

        Try
            Console.WriteLine("start to send encrypted email ...")
            oSmtp.SendMail(oServer, oMail)
            Console.WriteLine("email was sent successfully!")
        Catch ep As Exception
            Console.WriteLine("failed to send email with the following error:")
            Console.WriteLine(ep.Message)
        End Try
    End Sub
End Module

If you received digital signed and encrypted email by Windows Mail(Outlook Express), it looks like this:

VB.NET sign and encrypt email

Encryption Algorithm

You can use SmtpMail.EncryptionAlgorithm property to set RC2, RC4, 3DES, AES128, AES192 or AES256 encryption algorithm. RSAES-OAEP (AES128, AES192 and AES256) is recommended.

Next Section

At next section I will introduce how to send email with event handler.

Appendix

Comments

If you have any comments or questions about above example codes, please click here to add your comments.