Send Email with Event Handler in VB.NET

In previous section, I introduced how to encrypt email with digital certificate. In this section, I will introduce how to send email with event handler in VB.NET.

Introduction

In previous examples, after SendMail method is invoked, if you want to know the progress of the email sending, you should use Event Handler. The following sample codes demonstrate how to use Event Handler to monitor the progress of email sending.

Note

Remarks: All of samples in this section are based on first section: Send email in a simple VB.NET project. To compile and run the following example codes successfully, please click here to learn how to create the test project and add reference of EASendMail to your project.

[VB.NET - Send Email with Event Handler - Example]

The following example codes demonstrate how to send email with event handler in VB.NET.

Note

To get the full sample projects, please refer to Samples section.

Imports EASendMail 'Add EASendMail namespace
Module Module1
    Sub OnIdle(ByVal sender As Object, ByRef cancel As Boolean)
        ' this event is fired when the SmtpClient is wait for response from
        ' smtp server, if you add Application.DoEvents in windows form application,
        ' it can prevent your form has no response before SendMail is not returned.
        ' Application.DoEvents()
    End Sub
    Sub OnConnected(ByVal sender As Object, ByRef cancel As Boolean)
        Console.WriteLine("Connected")
    End Sub
    Sub OnSendingDataStream(ByVal sender As Object, ByVal sent As Integer, _
                          ByVal total As Integer, ByRef cancel As Boolean)
        Console.WriteLine(String.Format("{0}/{1} sent", sent, total))
    End Sub
    Sub OnAuthorized(ByVal sender As Object, ByRef cancel As Boolean)
        Console.WriteLine("Authorized")
    End Sub
    Sub OnSecuring(ByVal sender As Object, ByRef cancel As Boolean)
        Console.WriteLine("Securing ...")
    End Sub

    Sub Main()
        Dim oMail As New SmtpMail("TryIt")
        Dim oSmtp As New SmtpClient()
        ' Set sender email address, please change it to yours
        oMail.From = "test@emailarchitect.net"

        ' Set recipient email address, please change it to yours
        oMail.To = "support@emailarchitect.net"

        ' Set email subject
        oMail.Subject = "test email from VB.NET with event handler"

        ' Set email body
        oMail.TextBody = "this is a test email sent from VB.NET with event handler"

        ' Your SMTP server address
        Dim oServer As New SmtpServer("smtp.emailarchitect.net")

        ' User and password for ESMTP authentication, if your server doesn't require
        ' User authentication, please remove the following codes.
        oServer.User = "test@emailarchitect.net"
        oServer.Password = "testpassword"

        ' If your smtp server requires SSL/TLS connection, please add this line
        ' oServer.ConnectType = SmtpConnectType.ConnectSSLAuto

        ' Catching the following events is not necessary,
        ' just make the application more user friendly.
        ' If you use the object in asp.net/windows service or non-gui application,
        ' You need not to catch the following events.
        ' To learn more detail, please refer to the code in EASendMail EventHandler
        AddHandler oSmtp.OnIdle, AddressOf OnIdle
        AddHandler oSmtp.OnAuthorized, AddressOf OnAuthorized
        AddHandler oSmtp.OnConnected, AddressOf OnConnected
        AddHandler oSmtp.OnSecuring, AddressOf OnSecuring
        AddHandler oSmtp.OnSendingDataStream, AddressOf OnSendingDataStream

        Try
            Console.WriteLine("start to send email with event handler ...")
            oSmtp.SendMail(oServer, oMail)
            Console.WriteLine("email was sent successfully!")
        Catch ep As Exception
            Console.WriteLine("failed to send email with the following error:")
            Console.WriteLine(ep.Message)
        End Try
    End Sub
End Module

Next Section

At next section I will introduce how to send email asynchronously in VB.

Appendix

Comments

If you have any comments or questions about above example codes, please click here to add your comments.