1. Home
  2. EASendMail SMTP Component
  3. KB
  4. VB.NET
  5. Send Email Asynchronously in VB.NET

Tutorial Index

Send Email Asynchronously in VB.NET

In previous section, I introduced how to use event handler to monitor the progress. In this section, I will introduce how to send email in asynchronous mode in VB.NET.

Introduction

In synchronous mode, once SendMail method is called, it returns to application after the method is complete. Therefore, if the runtime (it depends on the networking connection and the email size) is long, your application cannot do anything before this method ends, which results “my application is blocked or halted”. In contrast, in asynchronous mode, as BeginSendMail method works in background, this methods return to application immediately no matter the running method is complete or not.

Note

Remarks: All of samples in this section are based on first section: Send email in a simple VB.NET project. To compile and run the following example codes successfully, please click here to learn how to create the test project and add reference of EASendMail to your project.

[VB.NET - Send Email Asynchronously - Example]

The following example codes demonstrate how to send email asynchronously in VB.NET.

Note

To get the full sample projects, please refer to Samples section.

Imports EASendMail 'Add EASendMail namespace

Module Module1

    Sub Main()

        Try
            Dim oMail As New SmtpMail("TryIt")

            ' Set sender email address, please change it to yours
            oMail.From = "test@emailarchitect.net"
            ' Set recipient email address, please change it to yours
            oMail.To = "support@emailarchitect.net"

            ' Set email subject
            oMail.Subject = "test asynchronous email from VB.NET"
            ' Set email body
            oMail.TextBody = "this is a test email sent from VB.NET with asynchronous mode"

            ' Your SMTP server address
            Dim oServer As New SmtpServer("smtp.emailarchitect.net")

            ' User and password for ESMTP authentication
            oServer.User = "test@emailarchitect.net"
            oServer.Password = "testpassword"

            ' Most mordern SMTP servers require SSL/TLS connection now.
            ' ConnectTryTLS means if server supports SSL/TLS, SSL/TLS will be used automatically.
            oServer.ConnectType = SmtpConnectType.ConnectTryTLS

            ' If your SMTP server uses 587 port
            ' oServer.Port = 587

            ' If your SMTP server requires SSL/TLS connection on 25/587/465 port
            ' oServer.Port = 25 ' 25 or 587 or 465
            ' oServer.ConnectType = SmtpConnectType.ConnectSSLAuto

            Console.WriteLine("start to send email in asynchronous mode ...")

            Dim oSmtp As New SmtpClient()
            Dim oResult As SmtpClientAsyncResult = oSmtp.BeginSendMail( _
                        oServer, oMail, Nothing, Nothing)
            ' Wait for the email sending...
            Do While (Not oResult.IsCompleted)
                Console.WriteLine("waiting..., you can do other thing!")
                oResult.AsyncWaitHandle.WaitOne(50, False)
            Loop

            oSmtp.EndSendMail(oResult)

        Catch ep As Exception
            Console.WriteLine("failed to send email with the following error:")
            Console.WriteLine(ep.Message)
        End Try

    End Sub

End Module

[VB.NET - Send Email with TAP (async, wait) - Example]

SmtpClient also supports task asynchronous programming model (TAP), you can use async and await to send email asynchronously.

Imports System.Threading.Tasks
Imports EASendMail 'Add EASendMail namespace

Module Module1
    Sub Main()
        Dim task = New Task(AddressOf SendMailAsync)

        ' Start and wait for task to end.
        task.Start()
        task.Wait()
        Console.ReadLine()

    End Sub

    Async Function SendMailAsync() As Task

        Try
            Dim oMail As New SmtpMail("TryIt")

            ' Set sender email address, please change it to yours
            oMail.From = "test@emailarchitect.net"
            ' Set recipient email address, please change it to yours
            oMail.To = "support@emailarchitect.net"

            ' Set email subject
            oMail.Subject = "test asynchronous email from VB.NET"
            ' Set email body
            oMail.TextBody = "this is a test email sent from VB.NET with asynchronous mode"

            ' Your SMTP server address
            Dim oServer As New SmtpServer("smtp.emailarchitect.net")

            ' User and password for ESMTP authentication
            oServer.User = "test@emailarchitect.net"
            oServer.Password = "testpassword"

            ' Most mordern SMTP servers require SSL/TLS connection now.
            ' ConnectTryTLS means if server supports SSL/TLS, SSL/TLS will be used automatically.
            oServer.ConnectType = SmtpConnectType.ConnectTryTLS

            ' If your SMTP server uses 587 port
            ' oServer.Port = 587

            ' If your SMTP server requires SSL/TLS connection on 25/587/465 port
            ' oServer.Port = 25 ' 25 or 587 or 465
            ' oServer.ConnectType = SmtpConnectType.ConnectSSLAuto

            Console.WriteLine("start to send email in asynchronous mode ...")

            Dim oSmtp As New SmtpClient()
            Await oSmtp.SendMailAsync(oServer, oMail)

            Console.WriteLine("email was sent successfully!")

        Catch ep As Exception
            Console.WriteLine("failed to send email with the following error:")
            Console.WriteLine(ep.Message)
        End Try

    End Function

End Module

Next Section

At next section I will introduce how to send mass email with multiple threads in VB.

Appendix

Comments

If you have any comments or questions about above example codes, please click here to add your comments.

See Also