WebDAV¶

If you want to leave a copy of email on the server, you should not call Delete method. However, there is a problem, how can you know if the email has already been downloaded (read)? If there is a way to identify the downloaded email, you can avoid downloading the duplicated email from your POP3/IMAP4 server.

Every email has a unique identifier (UIDL) on POP3 server. POP3 UIDL is only unique in the email life time. That means if the email was deleted from the server, other email can use the old unique identifier. Another problem is: UIDL in POP3 server can be any number or characters, so we cannot use UIDL as the file name, because UIDL may contain invalid characters for file name.

To solve this problem, we have to store the UIDL to a txt file and synchronize it with server every time.

The following delphi example codes demonstrate how to mark the email as downloaded/read on POP3 server.

Sections:

Installation
Add reference
Delphi - Mark email as read in POP3 - example
UIDL Manager
Delphi - Retrieve unread/new email in IMAP4/EWS/WebDAV - example
32bit/x64 ActiveX DLL
Distribution

Installation¶

Before you can use the following sample codes, you should download the EAGetMail Installer and install it on your machine at first. Full sample projects are included in this installer.

Add reference¶

To better demonstrate how to retrieve email and parse email, let’s create a Delphi Standard EXE project at first, then add a TButton on the Form, double-click this button. It is like this:

To use EAGetMail ActiveX Object in your Delphi project, the first step is “Add Unit file of EAGetMail to your project”. Please go to C:\Program Files\EAGetMail\Include\delphi or C:\Program Files (x86)\EAGetMail\Include\delphi folder, find EAGetMailObjLib_TLB.pas, and then copy this file to your project folder.

// include EAGetMailObjLib_TLB unit to your Delphi Project
unit Unit1;

interface

uses
Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
Dialogs, EAGetMailObjLib_TLB, StdCtrls;

Then you can start to use it in your Delphi Project.

You can also create EAGetMailObjLib_TLB.pas manually by Delphi like this:

Delphi 7 or eariler version

First of all, create a standard delphi project: select menu Project -> Import Type Library, checked EAGetMail ActiveX Object and click Create Unit. Then include EAGetMailObjLib_TLB in your project.
Delphi XE or later version

First of all, create a standard delphi project: select menu Component -> Import component... -> Import a type library -> checked EAGetMail ActiveX Object, have Generate Component Wrapper checked and click “Create Unit”. Then include EAGetMailObjLib_TLB in your project.

Delphi - Mark email as read in POP3 - example¶

The following example codes demonstrate marking email as read/downloaded on POP3 server. In order to run it correctly, please change email server, user, password, folder, file name value to yours.

Note

To get full sample projects, please download and install EAGetMail on your machine.

unit Unit1;

interface

uses
    Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
    Dialogs, StdCtrls, StrUtils, EAGetMailObjLib_TLB; // Add EAGetMail unit

type
    TForm1 = class(TForm)
        Button1: TButton;
        procedure Button1Click(Sender: TObject);

    private
        { Private declarations }

    public
        { Public declarations }
    end;

const
    MailServerPop3 = 0;
    MailServerImap4 = 1;
    MailServerEWS = 2;
    MailServerDAV = 3;
    MailServerMsGraph = 4;

var
    Form1: TForm1;

implementation

{$R *.dfm}


procedure TForm1.Button1Click(Sender: TObject);
var
    oServer: TMailServer;
    oClient: TMailClient;
    oTools: TTools;
    oMail: IMail;
    oUIDLManager: TUIDLManager;
    infos: IMailInfoCollection;
    oInfo: IMailInfo;
    localInbox, fileName, fullFileName: WideString;
    isUidlLoaded: Boolean;
    leaveCopy: Boolean;
    i: integer;
begin
    // set current thread code page to system default code page.
    SetThreadLocale(GetSystemDefaultLCID());

    // leave a copy of message on server
    leaveCopy := true;
    isUidlLoaded := false;

    // uidl is the identifier of every email on POP3/IMAP4 server, to avoid retrieve
    // the same email from server more than once, we record the email uidl retrieved every time
    // if you delete the email from server every time and not to leave a copy of email on
    // the server, then please remove all the function about uidl.
    oUIDLManager := TUIDLManager.Create(Application);

    try
        oTools := TTools.Create(Application);
        localInbox := GetCurrentDir() + '\inbox';
        oTools.CreateFolder(localInbox);

        oUIDLManager.Load(localInbox + '\uidl.txt');
        isUidlLoaded := true;

        oServer := TMailServer.Create(Application);
        oServer.Server := 'pop3.emailarchitect.net';
        oServer.User := 'test@emailarchitect.net';
        oServer.Password := 'testpassword';
        oServer.Protocol := MailServerPop3;

        // Enable SSL/TLS Connection, most modern email server require SSL/TLS connection by default.
        oServer.SSLConnection := true;
        // Set 995 SSL POP3 port
        oServer.Port := 995;

        // If your POP3 server doesn't deploy SSL connection
        // Please use
        // oServer.SSLConnection := false;
        // oServer.Port := 110;

        oClient := TMailClient.Create(Application);
        oClient.LicenseCode := 'TryIt';

        oClient.Connect1(oServer.DefaultInterface);
        ShowMessage( 'Connected!' );

        infos := oClient.GetMailInfoList();
        ShowMessage(Format('Total %d email(s)', [infos.Count]));

        // Remove the local uidl that is not existed on the server,
        oUIDLManager.SyncUIDLEX(oServer.DefaultInterface, infos);
        oUIDLManager.Update();

        for i := 0 to infos.Count - 1 do
            begin
                oInfo := infos.Item[i];

                // This email has not been retrieved before, then get it
                if oUIDLManager.FindUIDL(oServer.DefaultInterface, oInfo.UIDL) <> nil then
                    continue; // this email has been downloaded, do not receive it again

                // Generate a random file name by current local datetime,
                // You can use your method to generate the filename if you do not like it
                fileName := oTools.GenFileName(i) + '.eml';
                fullFileName := localInbox + '\' + fileName;

                // Receive email from POP3 server
                oMail := oClient.GetMail(oInfo);

                ShowMessage('From: ' + oMail.From.Address + #13#10 +
                    'Subject: ' + oMail.Subject);

                // Save email to local disk
                oMail.SaveAs(fullFileName, true);

                if leaveCopy Then
                    begin
                        // Add the email uidl to uidl file to avoid we retrieve it next time.
                        oUIDLManager.AddUIDL(oServer.DefaultInterface, oInfo.UIDL, fileName);
                    end
                else
                    begin
                        oClient.Delete(oInfo);

                        // Remove UIDL from local uidl file.
                        oUIDLManager.RemoveUIDL(oServer.DefaultInterface, oInfo.UIDL);
                    end;

            end;
        // Quit and expunge emails marked as deleted from POP3 server
        oClient.Quit;

    except
        on ep:Exception do
        ShowMessage( 'Error: ' + ep.Message );
    end;

    // Update the uidl list to a text file and then we can load it next time.
    if isUidlLoaded then
        oUIDLManager.Update();

end;

end.

UIDL Manager¶

UIDLManager provides an easier way to maintain UIDL between your server and your local client. It stores UIDL collection to a local disk file and you can use this object to add, remove and search UIDL with this local file.

Work with UIDL Manager

Delphi - Retrieve unread/new email in IMAP4/EWS/WebDAV - example¶

Because IMAP/EWS/WebDAV support read mail flag, with this feature, we can also retrieve unread/new email only from IMAP4/EWS/WebDAV like this

unit Unit1;

interface

uses
    Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
    Dialogs, StdCtrls, EAGetMailObjLib_TLB;

type
    TForm1 = class(TForm)
        Button1: TButton;
        procedure Button1Click(Sender: TObject);
    private
        { Private declarations }
    public
        { Public declarations }
    end;

const
    MailServerPop3 = 0;
    MailServerImap4 = 1;
    MailServerEWS = 2;
    MailServerDAV = 3;
    MailServerMsGraph = 4;

    // GetMailInfosParam Flags
    GetMailInfos_All = 1;
    GetMailInfos_NewOnly = 2;
    GetMailInfos_ReadOnly = 4;
    GetMailInfos_SeqRange = 8;
    GetMailInfos_UIDRange = 16;
    GetMailInfos_PR_ENTRYID = 32;
    GetMailInfos_DateRange = 64;
    GetMailInfos_OrderByDateTime = 128;

var
    Form1: TForm1;

implementation

{$R *.dfm}

procedure TForm1.Button1Click(Sender: TObject);
var
    oServer: TMailServer;
    oClient: TMailClient;
    oTools: TTools;
    oMail: IMail;
    infos: IMailInfoCollection;
    oInfo: IMailInfo;
    localInbox, fileName: WideString;
    i: Integer;
begin

    try
        // set current thread code page to system default code page.
        SetThreadLocale(GetSystemDefaultLCID());
        oTools := TTools.Create(Application);

        // Create a folder named "inbox" under
        // current directory to store the email files
        localInbox := GetCurrentDir() + '\inbox';
        oTools.CreateFolder(localInbox);

        oServer := TMailServer.Create(Application);
        oServer.Server := 'pop3.emailarchitect.net';
        oServer.User := 'test@emailarchitect.net';
        oServer.Password := 'testpassword';
        oServer.Protocol := MailServerImap4;

        // Enable SSL/TLS Connection, most modern email server require SSL/TLS connection by default.
        oServer.SSLConnection := true;
        // Set 993 SSL IMAP4 port
        oServer.Port := 993;

        // If your IMAP doesn't deploy SSL connection
        // Please use
        // oServer.SSLConnection := false;
        // oServer.Port := 143;

        oClient := TMailClient.Create(Application);
        oClient.LicenseCode := 'TryIt';

        oClient.Connect1(oServer.DefaultInterface);
        ShowMessage('Connected!');

        // retrieve unread/new email only
        oClient.GetMailInfosParam.Reset();
        oClient.GetMailInfosParam.GetMailInfosOptions := GetMailInfos_NewOnly;

        infos := oClient.GetMailInfoList();
        ShowMessage(Format('Total %d unread email(s)', [infos.Count]));

        for i := 0 to infos.Count - 1 do
            begin
                oInfo := infos.Item[i];

                ShowMessage(Format('Index: %d; Size: %d; UIDL: ' + oInfo.UIDL,
                [oInfo.Index, oInfo.Size]));

                // Generate a random file name by current local datetime,
                // You can use your method to generate the filename if you do not like it
                fileName := localInbox + '\' + oTools.GenFileName(i) + '.eml';

                // Receive email from POP3 server
                oMail := oClient.GetMail(oInfo);

                ShowMessage('From: ' + oMail.From.Address + #13#10 +
                    'Subject: ' + oMail.Subject);

                // Save email to local disk
                oMail.SaveAs(fileName, true);

                // mark unread email as read, next time this email won't be retrieved again
                if not oInfo.Read then
                    oClient.MarkAsRead(oInfo, true);

                // if you don't want to leave a copy on server, please use
                //  oClient.Delete(oInfo);
                // instead of MarkAsRead
            end;

        // Quit and expunge emails marked as deleted from POP3 server
        oClient.Quit;

    except
        on ep:Exception do
            ShowMessage('Error: ' + ep.Message);
    end;

end;

end.

32bit/x64 ActiveX DLL¶

Seperate builds of run-time dll for 32 and x64 platform

File	Platform
Installation Path\Lib\native\x86\EAGetMailObj.dll	32 bit
Installation Path\Lib\native\x64\EAGetMailObj.dll	64 bit

Distribution¶

Standard EXE

For VB6, C++, Delphi or other standard exe application, you can distribute EAGetMailObj.dll with your application to target machine without COM-registration and installer. To learn more detail, please have a look at Registration-free COM with Manifest File.
Script

For ASP, VBScript, VBA, MS SQL Stored Procedure, you need to install EAGetMail on target machine by EAGetMail installer, both 32bit/x64 DLL are installed and registered.

Tutorial Index