Verify Digital Signature and Decrypt Email in VB 6.0 - S/MIME¶

In previous section, I introduced how to parse email. In this section, I will introduce how to verify digital signature and decrypt email in VB 6.0.

Sections:

Introduction
[VB 6.0 Example - Verify digital signature and decrypt email]

Introduction¶

How to sign email?

Digital signature is always signed by sender certificate. The certificate used to sign email content MUST have the public/private key pair.

First of all, the user MUST get a digital certificate for personal email protection from third-party certificate authorities such as www.verisign.com.

After the certificate is installed on the machine, it can be viewed by Control Panel -> Internet Options -> Content -> Certificates -> Personal. When you view the certificate, please note there is a line “You have a private key that corresponds to this certificate” in the certificate view, that means you are able to use this certificate to sign email content. If this line doesn’t appear, that means you are unable to sign the email content by this certificate.

To sign email content, please refer to EASendMail SMTP Component.

How to encrypt email?

Encrypting email doesn’t require sender certificate but the certificate with public key for every recipient.

For example: from@adminsystem.com sends an email to rcpt@adminsystem.com with digital signature; The digital signature contains the public key certificate for from@adminsystem.com, then rcpt@adminsystem.com can send an encrypted email with this certificate back to from@adminsystem.com; Only from@adminsystem can read this email, because this email MUST be decrypted by private key of from@adminsystem.com.

Therefore, you MUST receive an digital signed email from other people (Most email clients such as outlook, outlook express will add the certificate to the Other People Storage automatically once an digital signed email is received) before you can send encrypted email to this people.

To encrypt email, please refer to EASendMail SMTP Component.

EAGetMail Mail class provides an easy way to verify the email digital signature and get the signer certificate. The signer certificate only contains the public key, that means you can add this certificate to your user certificate storage so that you can use this certificate to encrypt email and send the encrypted email back to the sender, only the sender can decrypt the email.

Note

Remarks: All of examples in this section are based on first section: A simple VB 6.0 project. To compile and run the following example codes successfully, please click here to learn how to create the test project and add reference to your project.

[VB 6.0 Example - Verify digital signature and decrypt email]¶

The following example codes demonstrate how to use EAGetMail POP3 component to verify digital signature and decrypt email.

Note

To get the full sample projects, please refer to Samples section.

Option Explicit

Const CRYPT_MACHINE_KEYSET = 32
Const CRYPT_USER_KEYSET = 4096
Const CERT_SYSTEM_STORE_CURRENT_USER = 65536
Const CERT_SYSTEM_STORE_LOCAL_MACHINE = 131072

Private Sub ParseEmail(ByVal emlFile As String)
    Dim oMail As New EAGetMailObjLib.Mail
    oMail.LicenseCode = "TryIt"

On Error GoTo ErrorHandle
    oMail.LoadFile emlFile, False

    If oMail.IsEncrypted Then
        ' This email is encrypted, we decrypt it by user default certificate.
        ' You can also use specified certificate like this
        ' Dim oCert As New EAGetMailObjLib.Certificate
        ' oCert.LoadFromFile "c:\test.pfx", "pfxpassword", CRYPT_USER_KEYSET
        ' Set oMail = oMail.Decrypt(oCert)
        Set oMail = oMail.Decrypt(Nothing)
    End If

    If oMail.IsSigned Then
        ' This email is digital signed.
        Dim oCert As EAGetMailObjLib.Certificate
        Set oCert = oMail.VerifySignature
        MsgBox "This email contains a valid digital signature."
        ' You can add the certificate to your certificate storage like this
        ' oCert.AddToStore CERT_SYSTEM_STORE_CURRENT_USER, "addressbook"
        ' Then you can use send the encrypted email back to this sender.
    End If

    ' Parse email sender
    MsgBox "From: " & oMail.From.Address

    Dim addressList As EAGetMailObjLib.AddressCollection
    Dim i As Long
    Dim addr As EAGetMailObjLib.MailAddress

    ' Parse email to recipients
    Set addressList = oMail.ToList
    For i = 0 To addressList.Count - 1
        Set addr = addressList.Item(i)
        MsgBox "To: " & addr.Address
    Next

    ' Parse email cc
    Set addressList = oMail.CcList
    For i = 0 To addressList.Count - 1
        Set addr = addressList.Item(i)
        MsgBox "Cc: " & addr.Address
    Next

    ' Parse email subject
    MsgBox "Subject: " & oMail.Subject

    ' Parse email text body
    MsgBox "Text body: " & oMail.TextBody

    ' Parse email HTML body
    MsgBox "Html body: " & oMail.HtmlBody

    ' Parse attachments
    Dim atts As EAGetMailObjLib.AttachmentCollection
    Dim att As EAGetMailObjLib.Attachment

    Set atts = oMail.AttachmentList
    For i = 0 To atts.Count - 1
        Set att = atts.Item(i)
        MsgBox "Attachment: " & att.name
        ' Save attachment to local file.
        att.SaveAs App.Path & "\inbox\" & att.name, True
    Next

    Exit Sub
ErrorHandle:
    MsgBox Err.Description
End Sub

Private Sub Command1_Click()
    Dim curpath As String
    Dim mailbox As String
    Dim oTools As New EAGetMailObjLib.Tools

    ' Create a folder named "inbox" under current directory
    ' to save the email retrieved.
    curpath = App.Path
    mailbox = curpath & "\inbox"
    oTools.CreateFolder mailbox

    Dim files
    Dim i As Long

    ' Get all *.eml files in specified folder and parse it one by one.
    files = oTools.GetFiles(mailbox & "\*.eml")
    For i = LBound(files) To UBound(files)
        ParseEmail files(i)
    Next

    Exit Sub
ErrorHandle:
    MsgBox Err.Description
End Sub

Next Section

At next section I will introduce how to parse MAPI winmail.dat (TNEF/MAPI) attachment.

Tutorial Index

Verify Digital Signature and Decrypt Email in VB 6.0 - S/MIME¶

Introduction¶

[VB 6.0 Example - Verify digital signature and decrypt email]¶

Share

See Also