Download/Retrieve Email from Gmail account in VB 6.0

In previous section, I introduced how to retrieve email over SSL connection. In this section, I will introduce how to download email from your Gmail account in VB 6.0.

Introduction

Gmail POP3 server address is pop.gmail.com. It requires SSL connection on 995 port, and you should use your Gmail email address as the user name for user authentication.

Gmail IMAP4 server address is imap.gmail.com. It requires SSL connection on 993 port, and you should use your Gmail email address as the user name for user authentication. For example: your email is gmailid@gmail.com, and then the user name should be gmailid@gmail.com.

To retrieve email from Gmail account, you need to enable POP3 or IMAP4 access in your gmail account settings.

Because Gmail POP3 server doesn’t work like normal POP3 server, it hides old emails automatically even the email was not deleted, so we suggest that you use IMAP4 protocol.

Server Port SSL Protocol
pop.gmail.com 995 SSL required Pop3
imap.gmail.com 993 SSL required Imap4 (recommended)

Important

If you got authentication error, you need to enable Allowing less secure apps or Sign in using App Passwords.

Another way is Gmail OAUH, please see Gmail IMAP OAUTH section.

Note

Remarks: All of examples in this section are based on first section: A simple VB 6.0 project. To compile and run the following example codes successfully, please click here to learn how to create the test project and add reference to your project.

[VB 6.0 Example - Retrieve email from Gmail account]

The following example codes demonstrate how to download email from Gmail account using IMAP4 protocol.

Because Gmail POP3 server doesn’t work like normal POP3 server, it hides old emails automatically even the email was not deleted, so we suggest that you use IMAP4 protocol.

Note

To get the full sample projects, please refer to Samples section.

Option Explicit

Const MailServerPop3 = 0
Const MailServerImap4 = 1
Const MailServerEWS = 2
Const MailServerDAV = 3

Private Sub Command1_Click()
    Dim curpath As String
    Dim mailbox As String
    Dim oTools As New EAGetMailObjLib.Tools

    ' Create a folder named "inbox" under current directory
    ' to save the email retrieved.
    curpath = App.Path
    mailbox = curpath & "\inbox"
    oTools.CreateFolder mailbox

    Dim oServer As New EAGetMailObjLib.MailServer
    ' Gmail IMAP server address
    oServer.Server = "imap.gmail.com"
    oServer.User = "gmailid@gmail.com"
    oServer.Password = "testpassword"
    oServer.Protocol = MailServerImap4

    ' Enable SSL Connection
    oServer.SSLConnection = True

    ' Set 993 SSL Port
    oServer.Port = 993

    On Error GoTo ErrorHandle:
    Dim oClient As New EAGetMailObjLib.MailClient
    oClient.LicenseCode = "TryIt"

    oClient.Connect oServer
    MsgBox "Connected"

    Dim infos
    infos = oClient.GetMailInfos()
    MsgBox UBound(infos) + 1 & " emails"

    Dim i As Integer
    For i = LBound(infos) To UBound(infos)
        Dim info As EAGetMailObjLib.MailInfo
        Set info = infos(i)
        MsgBox "Index: " & info.Index & "; Size: " & info.Size & _
        "; UIDL: " & info.UIDL

        ' Receive email from Gmail server
        Dim oMail As EAGetMailObjLib.Mail
        Set oMail = oClient.GetMail(info)

        MsgBox "From: " & oMail.From.Address & _
            vbCrLf & "Subject: " & oMail.Subject

        Dim fileName As String
        ' Generate a random file name by current local datetime,
        ' You can use your method to generate the filename if you do not like it
        fileName = mailbox & "\" & oTools.GenFileName(i) & ".eml"

        ' Save email to local disk
        oMail.SaveAs fileName, True

        ' Mark email as deleted from Gmail server.
        oClient.Delete info
    Next

    ' Quit and purge emails marked as deleted from Gmail server.
    oClient.Quit
    Exit Sub

ErrorHandle:
    MsgBox Err.Description
End Sub

Gmail IMAP OAUTH

The Gmail IMAP and SMTP servers have been extended to support authorization via the industry-standard OAuth 2.0 protocol. Using OAUTH protocol, user can do authentication by Gmail Web OAuth instead of inputting user and password directly in application. This way is more secure, but a little bit complex.

Using Gmail IMAP OAUTH

Next Section

At next section I will introduce how to download emails from Yahoo account.

Appendix

Comments

If you have any comments or questions about above example codes, please click here to add your comments.