1. Home
  2. EAGetMail POP3/IMAP4 Component
  3. KB
  4. VB6
  5. Download/Retrieve Email from Gmail account in VB 6.0

Tutorial Index

Download/Retrieve Email from Gmail account in VB 6.0

In previous section, I introduced how to retrieve email over SSL connection. In this section, I will introduce how to download email from your Gmail account in VB 6.0.

Introduction

Gmail POP3 server address is pop.gmail.com. It requires SSL connection on 995 port, and you should use your Gmail email address as the user name for user authentication.

Gmail IMAP4 server address is imap.gmail.com. It requires SSL connection on 993 port, and you should use your Gmail email address as the user name for user authentication. For example: your email is gmailid@gmail.com, and then the user name should be gmailid@gmail.com.

To retrieve email from Gmail account, you need to enable POP3 or IMAP4 access in your gmail account settings.

Because Gmail POP3 server doesn’t work like normal POP3 server, it hides old emails automatically even the email was not deleted, so we suggest that you use IMAP4 protocol.

Server Port SSL Protocol
pop.gmail.com 995 SSL required Pop3
imap.gmail.com 993 SSL required Imap4 (recommended)

Gmail App Password

To help keep your account secure, starting May 30, 2022, ​​Google will no longer support the use of third-party apps or devices which ask you to sign in to your Google Account using only your username and password.

Therefore, you should sign in using App Passwords. An App Password is a 16-digit passcode that gives a less secure app or device permission to access your Google Account. App Passwords can only be used with accounts that have 2-Step Verification turned on. You need to use App Password instead of the user password for user authentication.

Another solution is Gmail OAUH, please see Gmail IMAP OAUTH section.

Note

Remarks: All of examples in this section are based on first section: A simple VB 6.0 project. To compile and run the following example codes successfully, please click here to learn how to create the test project and add reference to your project.

[VB 6.0 Example - Retrieve email from Gmail account]

The following example codes demonstrate how to download email from Gmail account using IMAP4 protocol.

Because Gmail POP3 server doesn’t work like normal POP3 server, it hides old emails automatically even the email was not deleted, so we suggest that you use IMAP4 protocol.

Note

To get the full sample projects, please refer to Samples section.

Option Explicit

Const MailServerPop3 = 0
Const MailServerImap4 = 1
Const MailServerEWS = 2
Const MailServerDAV = 3
Const MailServerMsGraph = 4

Private Sub Command1_Click()
    Dim curpath As String
    Dim mailbox As String
    Dim oTools As New EAGetMailObjLib.Tools

    ' Create a folder named "inbox" under current directory
    ' to save the email retrieved.
    curpath = App.Path
    mailbox = curpath & "\inbox"
    oTools.CreateFolder mailbox

    Dim oServer As New EAGetMailObjLib.MailServer
    ' Gmail IMAP server address
    oServer.Server = "imap.gmail.com"
    oServer.User = "gmailid@gmail.com"

    ' Create app password in Google account
    ' https://support.google.com/accounts/answer/185833?hl=en
    oServer.Password = "your app password"
    oServer.Protocol = MailServerImap4

    ' Enable SSL Connection
    oServer.SSLConnection = True

    ' Set 993 SSL Port
    oServer.Port = 993

On Error GoTo ErrorHandle:
    Dim oClient As New EAGetMailObjLib.MailClient
    oClient.LicenseCode = "TryIt"

    oClient.Connect oServer
    MsgBox "Connected"

    Dim infos As EAGetMailObjLib.MailInfoCollection
    Set infos = oClient.GetMailInfoList()
    MsgBox infos.Count & " emails"

    Dim i As Long
    For i = 0 To infos.Count - 1
        Dim info As EAGetMailObjLib.MailInfo
        Set info = infos.Item(i)

        MsgBox "Index: " & info.Index & "; Size: " & info.Size & _
        "; UIDL: " & info.UIDL

        ' Receive email from Gmail server
        Dim oMail As EAGetMailObjLib.Mail
        Set oMail = oClient.GetMail(info)

        MsgBox "From: " & oMail.From.Address & _
            vbCrLf & "Subject: " & oMail.Subject

        Dim fileName As String
        ' Generate a random file name by current local datetime,
        ' You can use your method to generate the filename if you do not like it
        fileName = mailbox & "\" & oTools.GenFileName(i) & ".eml"

        ' Save email to local disk
        oMail.SaveAs fileName, True

        ' Mark email as deleted from Gmail server.
        oClient.Delete info
    Next

    ' Quit and expunge emails marked as deleted from Gmail server.
    oClient.Quit
    Exit Sub

ErrorHandle:
    MsgBox Err.Description
End Sub

Gmail IMAP OAUTH

By default, you can generate an App Passwords, and use this app password instead of the user password for IMAP4 authentication.

However, Google will disable traditional user authentication in the future, switching to Google OAuth is strongly recommended now.

[VB 6.0 Example - Retrieve Unread/New Email from Gmail Account]

Because IMAP/EWS/WebDAV support read mail flag, with this feature, we can also retrieve unread/new email only from Gmail like this

Option Explicit

Const MailServerPop3 = 0
Const MailServerImap4 = 1
Const MailServerEWS = 2
Const MailServerDAV = 3
Const MailServerMsGraph = 4

Const GetMailInfos_All = 1
Const GetMailInfos_NewOnly = 2
Const GetMailInfos_ReadOnly = 4
Const GetMailInfos_SeqRange = 8
Const GetMailInfos_UIDRange = 16
Const GetMailInfos_PR_ENTRYID = 32
Const GetMailInfos_DateRange = 64
Const GetMailInfos_OrderByDateTime = 128

Private Sub Command1_Click()
    Dim curpath As String
    Dim mailbox As String
    Dim oTools As New EAGetMailObjLib.Tools

    ' Create a folder named "inbox" under current directory
    ' to save the email retrieved.
    curpath = App.Path
    mailbox = curpath & "\inbox"
    oTools.CreateFolder mailbox

    Dim oServer As New EAGetMailObjLib.MailServer
    ' Gmail IMAP server address
    oServer.Server = "imap.gmail.com"
    oServer.User = "gmailid@gmail.com"

    ' Create app password in Google account
    ' https://support.google.com/accounts/answer/185833?hl=en
    oServer.Password = "your app password"
    oServer.Protocol = MailServerImap4

    ' Enable SSL Connection
    oServer.SSLConnection = True

    ' Set 993 SSL Port
    oServer.Port = 993

On Error GoTo ErrorHandle:
    Dim oClient As New EAGetMailObjLib.MailClient
    oClient.LicenseCode = "TryIt"

    oClient.Connect oServer
    MsgBox "Connected"

    ' retrieve unread/new email only
    oClient.GetMailInfosParam.Reset
    oClient.GetMailInfosParam.GetMailInfosOptions = GetMailInfos_NewOnly

    Dim infos As EAGetMailObjLib.MailInfoCollection
    Set infos = oClient.GetMailInfoList()
    MsgBox infos.Count & " unread emails"

    Dim i As Long
    For i = 0 To infos.Count - 1
        Dim info As EAGetMailObjLib.MailInfo
        Set info = infos.Item(i)

        MsgBox "Index: " & info.Index & "; Size: " & info.Size & _
        "; UIDL: " & info.UIDL

        ' Receive email from Gmail server
        Dim oMail As EAGetMailObjLib.Mail
        Set oMail = oClient.GetMail(info)

        MsgBox "From: " & oMail.From.Address & _
            vbCrLf & "Subject: " & oMail.Subject

        Dim fileName As String
        ' Generate a random file name by current local datetime,
        ' You can use your method to generate the filename if you do not like it
        fileName = mailbox & "\" & oTools.GenFileName(i) & ".eml"

        ' Save email to local disk
        oMail.SaveAs fileName, True

        ' mark unread email as read, next time this email won't be retrieved again
        If Not info.Read Then
            oClient.MarkAsRead info, True
        End If

        ' if you don't want to leave a copy on server, please use
        ' oClient.Delete info
        ' instead of MarkAsRead
    Next

    ' Quit and expunge emails marked as deleted from Gmail server.
    oClient.Quit
    Exit Sub

ErrorHandle:
    MsgBox Err.Description
End Sub

TLS 1.2

TLS is the successor of SSL, more and more Email servers require TLS 1.2 encryption now.

If your operating system is Windows XP/Vista/Windows 7/Windows 2003/2008/2008 R2/2012/2012 R2, and you got connection error with SSL/TLS connection, you need to enable TLS 1.2 protocol in your operating system like this:

Enable TLS 1.2 on Windows XP/Vista/7/10/Windows 2008/2008 R2/2012

Next Section

At next section I will introduce how to download emails from Yahoo account.

Appendix

Comments

If you have any comments or questions about above example codes, please click here to add your comments.

See Also